M2 – Page 18 – The Smell of Molten Projects in the Morning

Fu Mask Cutting Templates

A local hospital contacted Mary’s quilting group to sew up cloth covers to prolong the life of their medical-grade N95 masks. Their recommended pattern, the Fu Face Mask from the FreeSewing group, comes in three sizes:

Freesewing - Fu Mask — Freesewing – Fu Mask

N.B.: Use their original PDF, because a JPG picture probably won’t come out at the right size.

Also N.B.: Used by itself, this is not a medical-grade filter mask.

The patterns do not include the usual 1/4 inch seam allowance around the outside, so I cranked out 3D printed plastic cutting templates.

If you’re not interested in 3D printing, 2D print the PDF file on cardboard, sketch a seam allowance, and cut it out, as quilters have been doing since slightly after home printers happened.

The plan of attack:

Convert mask outlines into a bitmap image (GIMP)
Create Bezier curves by tracing outlines (Inkscape)
Save curves as SVG files
Convert SVG into solid model (OpenSCAD)
Add stiffening ribs &c
Save as STL solid model
Slice into G-Code file (Slic3r)
Fire the M2!

So, we begin …

Import the PDF into The GIMP, delete the text & suchlike, convert to monochrome, and save the pattern outlines as a PNG file:

Fu Facemask - outlines — Fu Facemask – outlines

It turns out Inkscape can directly import the PDF, but it valiantly tries to convert all the text and the incidental graphic elements, none of which will be useful in this situation. It’s easier to delete them in The GIMP and make a bank shot off a PNG file.

Update: Scruss’s comment provides a much simpler workflow!

Import the PNG into Inkscape and trace one outline with the Bezier curve tool:

Fu Mask - Inkscape Bezier trace — Fu Mask – Inkscape Bezier trace

If you squint really carefully, you’ll see Bezier control handles sticking out of the nodes. I laid three nodes along the top arc and four along the right side, but do what’cha like; the Insert key or Shift+I inserts and Delete removes nodes. It’s easier to center a node in the middle of the PNG line with snapping turned off: Shift+drag while mousing or globally with #.

You could unleash the bitmap auto-tracer, but it generates a bazillion uselessly tiny Bezier curves.

When you’re happy, select and copy the path with Ctrl+C, paste it into a shiny new Inkscape document (Ctrl+N) with Ctrl-V, save it with a catchy file name like Fu Mask - Small - nominal.svg, and close that document to return to the document with the PNG outlines and the original path.

Select the original path again, create a dynamic offset with Ctrl+J, open the XML editor with Ctrl+Shift+X (which automagically selects the proper SVG element), and change the inkscape:radius value from 0 to 6.35 (mm, which everyone should use) to get a 1/4 inch seam allowance:

Fu Mask - Inkscape XML Editor - Offset radius — Fu Mask – Inkscape XML Editor – Offset radius

The path will puff out with curved corners:

Fu Mask - Inkscape offset — Fu Mask – Inkscape offset

Copy into a new document, save as Fu Mask - Small - seam allowance.svg, and close.

Repeat that process for each of the three mask sizes to create three pairs of SVG files: the nominal mask outline and the corresponding seam allowance outline for each size.

The OpenSCAD program imports the SVG files, removes the nominal outline from within the seam allowance to leave the outline, adds stiffening ribs, and stamps an ID letter on both sides of the central button:

Fu Mask Cutting Template - Small - solid model — Fu Mask Cutting Template – Small – solid model

Choose one of the three sizes with the OpenSCAD customizer, save the resulting model as an STL file, repeat for the three sizes, and you’re done.

This process can convert any outline paths in SVG files into cutting templates, so, should the Fu Mask not suit your fancy, Use The Source.

For convenience, the STL files are on Thingiverse.

From the comments, a Washington hospital uses a similar pattern: their PDF with assembly instructions.

The OpenSCAD source code as a GitHub Gist:

	// Fu Mask cutting templates
	// Ed Nisley – KE4ZNU – 2020-03
	// Mask patterns from:
	// https://freesewing.org/blog/facemask-frenzy/
	// More info on my blog:
	// https://softsolder.com/2020/03/29/fu-mask-cutting-templates/

	/* [Mask Size] */

	Name = "Small"; // [Small, Medium, Large, Test]

	/* [Hidden] */

	Templates = [ // center ID letter and file name
	["S","Small"],
	["M","Medium"],
	["L","Large"],
	["T","Test"], // for whatever you like
	];

	T_ID = 0; // Template indexes
	T_NAME = 1;

	BarThick = 4.0; // template thickness
	HubOD = 20.0; // center button diameter

	// These should match slicer values

	ThreadThick = 0.25;
	ThreadWidth = 0.40;

	Protrusion = 0.1; // make clean holes

	//— Build it

	t = Templates[search([Name],Templates,1,1)[0]]; // find template index

	Dir = "./";

	FnOuter = str(Dir,"Fu Facemask – ",t[T_NAME]," – seam allowance.svg");
	FnInner = str(Dir,"Fu Facemask – ",t[T_NAME]," – nominal.svg");

	difference() {
	linear_extrude(BarThick,convexity=5) {

	intersection() {
	import(FnOuter,center=true);
	union() {
	square([200.0,5.0],center=true); // horizontal bar
	square([5.0,200.0],center=true); // vertical bar
	}
	}

	circle(d=HubOD); // central button

	difference() { // cutting template!
	import(FnOuter,center=true);
	import(FnInner,center=true);
	}

	}

	translate([0,0,BarThick – ThreadThick]) // top ID recess
	cylinder(d=HubOD – 6*ThreadWidth,h=ThreadThick + Protrusion);

	translate([0,0,-Protrusion]) // bottom ID recess
	cylinder(d=HubOD – 6*ThreadWidth,h=ThreadThick + Protrusion);

	}

	translate([0,0,2*BarThick/3]) // top ID
	linear_extrude(height=BarThick/3,convexity=2)
	text(text=t[T_ID],size=10,
	font="Arial:style:Bold",halign="center",valign="center");

	mirror([1,0,0]) // bottom ID
	linear_extrude(height=BarThick/3,convexity=2)
	text(text=t[T_ID],size=10,
	font="Arial:style:Bold",halign="center",valign="center");

view raw Fu Mask Cutting Template.scad hosted with ❤ by GitHub

Verily, there’s nothing like a good new problem to take your mind off all your old problems …

2020-03-29

Round Soaker Hose Splint

One of two new round rubber soaker hoses arrived with a slight crimp, enough to suggest it would crumble at an inopportune moment. Rather than return the hose for something that’s not an obvious failure, I clamped the crimp:

Round Soaker Hose Splice - top — Round Soaker Hose Splice – top

Unlike the clamps for the punctured flat soaker hoses, this one doesn’t need to withstand much pressure and hold back a major leak, so I made the pieces a bit thicker and dispensed with the aluminum backing plates:

Round Soaker Hose Splice - bottom — Round Soaker Hose Splice – bottom

The solid model is basically the same as for the flat hoses, with a slightly oval cylinder replacing the three channels:

Round Soaker Hose Splice - OpenSCAD model — Round Soaker Hose Splice – OpenSCAD model

The OpenSCAD source code as a GitHub Gist:

	// Rubber Soaker Hose Splice
	// Ed Nisley KE4ZNU 2020-03

	Layout = "Build"; // [Hose,Block,Show,Build]

	TestFit = false; // true to build test fit slice from center

	//- Extrusion parameters must match reality!

	/* [Hidden] */

	ThreadThick = 0.25;
	ThreadWidth = 0.40;

	HoleWindage = 0.2;

	Protrusion = 0.1; // make holes end cleanly

	inch = 25.4;

	function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

	ID = 0;
	OD = 1;
	LENGTH = 2;


	//———-
	// Dimensions
	// Hose lies along X axis

	Hose = [200,14.5,13.6]; // X = longer than anything else

	// 8-32 stainless screws
	Screw = [4.1,8.0,3.0]; // OD = head LENGTH = head thickness
	Washer = [4.4,9.5,1.0];
	Nut = [4.1,9.7,6.0];

	Block = [50.0,Hose.y + 2Washer[OD],4.0 + 1.5Hose.z]; // overall splice block size
	echo(str("Block: ",Block));

	Kerf = 1.0; // cut through middle to apply compression

	CornerRadius = Washer[OD]/2;

	NumScrews = 3; // screws along each side of cable
	ScrewOC = [(Block.x – 2*CornerRadius) / (NumScrews – 1),
	Block.y – 2*CornerRadius,
	2*Block.z // ensure complete holes
	];

	echo(str("Screw OC: x=",ScrewOC.x," y=",ScrewOC.y));

	//———————-
	// Useful routines

	module PolyCyl(Dia,Height,ForceSides=0) { // based on nophead's polyholes
	Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);
	FixDia = Dia / cos(180/Sides);
	cylinder(d=(FixDia + HoleWindage),h=Height,$fn=Sides);
	}

	// Hose shape
	// This includes magic numbers measured from reality

	module HoseProfile() {

	NumSides = 12*4;

	rotate([0,-90,0])
	translate([0,0,-Hose.x/2])
	resize([Hose.z,Hose.y,0])
	cylinder(d=Hose.z,h=Hose.x,$fn=NumSides);
	}

	// Outside shape of splice Block
	// Z centered on hose rim circles, not overall thickness through center ridge

	module SpliceBlock() {
	difference() {
	hull()
	for (i=[-1,1], j=[-1,1]) // rounded block
	translate([i(Block.x/2 – CornerRadius),j(Block.y/2 – CornerRadius),-Block.z/2])
	cylinder(r=CornerRadius,h=Block.z,$fn=4*8);
	for (i = [0:NumScrews – 1], j=[-1,1]) // screw holes
	translate([-(Block.x/2 – CornerRadius) + i*ScrewOC.x,
	j*ScrewOC.y/2,
	-(Block.z/2 + Protrusion)])
	PolyCyl(Screw[ID],Block.z + 2*Protrusion,6);
	cube([2Block.x,2Block.y,Kerf],center=true); // slice through center
	}
	}

	// Splice block less hose

	module ShapedBlock() {
	difference() {
	SpliceBlock();
	HoseProfile();
	}
	}




	//———-
	// Build them

	if (Layout == "Hose")
	HoseProfile();

	if (Layout == "Block")
	SpliceBlock();

	if (Layout == "Show") {
	difference() {
	SpliceBlock();
	HoseProfile();
	}
	color("Green",0.25)
	HoseProfile();
	}

	if (Layout == "Build") {
	SliceOffset = TestFit && !NumScrews%2 ? ScrewOC.x/2 : 0;
	intersection() {
	translate([SliceOffset,0,Block.z/4])
	if (TestFit)
	cube([ScrewOC.x/2,4*Block.y,Block.z/2],center=true);
	else
	cube([4Block.x,4Block.y,Block.z/2],center=true);
	union() {
	translate([0,0.6*Block.y,Block.z/2])
	ShapedBlock();
	translate([0,-0.6*Block.y,Block.z/2])
	rotate([0,180,0])
	ShapedBlock();
	}
	}
	}

view raw Round Soaker Hose Splice.scad hosted with ❤ by GitHub

2020-03-20

HON Lateral File: Shelf Rebuild

After sliding the HON Lateral File Cabinet shelf into place and installing the bumpers, it seemed rather loose and floppy. Comparing the situation with the other file cabinet showed it had a missing glide button in the rear and two missing slides at the front.

A replacement button emerged from the end of a Delrin rod:

The original buttons had an expanding stem, which is easy to do with an injection-molded part. I opted for simple adhesive, with enough of a blob underneath the shelf to (presumably) lock it in place forevermore:

The slides required an iterative design technique (pronounced “fumbling around”), because nothing on either side remained square / plumb / true / unbent. I hacked the first version from scrap acrylic, broke off anything that didn’t fit, and got better measurements from what remained:

HON Lateral File - shelf front guide - size test — HON Lateral File – shelf front guide – size test

With those measurements in hand, the second version used a pair of weird flat-head shoulder screws (probably from a hard drive) to anchor 3D printed angle brackets into the frame:

HON Lateral File - shelf slides - version 2 — HON Lateral File – shelf slides – version 2

Those worked reasonably well, but PETG doesn’t produce a nice sliding surface, so the final version has flat-head Delrin studs in slightly tweaked brackets:

HON Lateral File - shelf slides - version 3 — HON Lateral File – shelf slides – version 3

As with the buttons in the back, the original slides had expanding studs holding them in place, but glue works fine here, too:

HON Lateral File - shelf slides - version 3 - installed — HON Lateral File – shelf slides – version 3 – installed

The button isn’t quite square to the surface and the slide isn’t quite flush with the bent metal in the frame, but it’s Good Enough™ for a shelf that won’t get lots of mileage.

For reference, the brackets should print vertically to wrap the plastic threads around the upright for better strength:

HON Lateral File Shelf Slide - Slic3r — HON Lateral File Shelf Slide – Slic3r

If you did it the obvious way, the upright side would break right off at the first insult from the hulking shelf, although they’re basically a solid chip of plastic, with a little infill inside the bottom slab.

While I was at it, I pulled the springs to make them a bit longer, so they touch the back of the frame when the shelf is half an inch behind the front face of the drawers. A firm push and those Delrin contact points let the shelf pop out an inch or so, with plenty of room for fingers underneath the front edge.

Some drawer slide stops near the back needed attention, too:

HON Lateral File - slide stop bumper - bent — HON Lateral File – slide stop bumper – bent

I cannot imagine how hard somebody slammed the drawers, because bending the stops back to a right angle required a Vise-Grip and some muttering:

HON Lateral File - slide stop bumper — HON Lateral File – slide stop bumper

Oddly, the cushiony hollow side faces away from the drawer, toward the back of the frame, because putting it forward holds the drawer front proud of the front frame face. Maybe HON cost-reduced the steel slides by making them just slightly shorter and using the same bumpers?

The drawers have begun filling up from boxes scattered around the house:

HON Lateral File - fabric stash — HON Lateral File – fabric stash

That’s the “orange” part of Mary’s collection, now with plenty of room to grow!

The OpenSCAD source code as a GitHub Gist:

	// HON Lateral File Cabinet
	// Shelf slides
	// Ed Nisley KE4ZNU 2020-02-25

	//- Extrusion parameters must match reality!
	// Print with 3 shells and 3 solid layers

	ThreadThick = 0.25;
	ThreadWidth = 0.40;

	HoleWindage = 0.2;

	function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

	Protrusion = 0.1; // make holes end cleanly

	inch = 25.4;

	ID = 0;
	OD = 1;
	LENGTH = 2;


	module PolyCyl(Dia,Height,ForceSides=0) { // based on nophead's polyholes

	Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);
	FixDia = Dia / cos(180/Sides);
	cylinder(r=(FixDia + HoleWindage)/2,h=Height,$fn=Sides);
	}

	//———————-
	// Dimensions

	SlideBlock = [18.0,25.0,12.0]; // across, along, height of left shelf bracket

	SlideWalls = [1.0,-SlideBlock.y/2,2.0]; // wall thicknesses, dummy Y

	HoleOffset = [8.4,7.0,0]; // hole center from left, front, dummy Z
	HoleOD = 4.0;

	Screw = [4.0,10,0.8]; // weird flat-head shoulder screw

	ScrewRecess = Screw.z + 2*ThreadThick; // depth to keep head below slide surface

	echo(str("Head base: ",SlideWalls.z – ScrewRecess));

	$fn = 12*4;

	//——————-
	// Single slide

	module Slide() {

	difference() {
	cube(SlideBlock,center=false);

	translate(SlideWalls)
	cube(SlideBlock * 2,center=false);

	translate(HoleOffset – [0,0,SlideBlock.z/2])
	rotate(180/8)
	PolyCyl(HoleOD,2*SlideBlock.z,8);

	translate(HoleOffset + [0,0,SlideWalls.z] – [0,0,ScrewRecess])
	rotate(180/12)
	PolyCyl(Screw[OD],3*Screw[LENGTH],12);
	}

	}



	//——————-
	// Build them

	Gap = 5.0/2;

	translate([0,-Gap,0])
	rotate([90,0,0])
	Slide();

	translate([0,Gap,0])
	rotate([-90,0,0])
	mirror([0,1,0])
	Slide();

view raw HON Lateral File Shelf Slides.scad hosted with ❤ by GitHub

2020-03-02

Refrigerator Coil Wand Adapter Rebuild

After five years, the adapter between the Kenmore Progressive vacuum cleaner and the long wand required to reach inside the refrigerator evaporator coils broke at the latch opening:

Kenmore Vacuum - refrigerator coil adapter - fracture — Kenmore Vacuum – refrigerator coil adapter – fracture

A quick fix let me continue the mission:

Kenmore Vacuum - refrigerator coil adapter - temporary fix — Kenmore Vacuum – refrigerator coil adapter – temporary fix

A better fix required a few minutes of OpenSCAD tweakage and a few hours of hands-off build time:

Refrigerator Coil Wand Adapter - Slic3r preview — Refrigerator Coil Wand Adapter – Slic3r preview

The fitting ID is now 2 mm smaller, the 3D honeycomb infill is 25%, and (contrary to the picture) it now has 4 perimeter threads. It’s a two-line change from the last time:

OEMTube = [35.0 - 2.0,35.0,41.7,40.5,30.0];           // main fitting tube
… then, inside MaleFitting() …
cylinder(d1=OEMTube[ID2],d2=OEMTube[ID1],h=2*OEMTube[LENGTH] + 2*Protrusion);

Those will propagate to anything I build from now on, although this is the first latch fracture.

Gotta love it when 3D printing lives up to the hype!

2020-02-25

Bird Box Entrance Reducers: Round 2

One of the bird box entrance reducers I installed nigh onto a decade ago is still on duty, although downy woodpeckers definitely want a larger hole:

Bird Box - gray PVC pipe reducer - woodpecker damage — Bird Box – gray PVC pipe reducer – woodpecker damage

Another reducer had gone missing over the years, so I made one from a length of PVC pipe:

Bird Box - PVC pipe reducer - shaping — Bird Box – PVC pipe reducer – shaping

It started as 1-½ PVC pipe, 1-⅞ inch actual OD and should fit into a 1-½ hole, so I measured 1.5 × 3.15 around the circumference, bandsawed out the excess, draped it over a 1-½ Forstner bit, toasted it with a heat gun, and squashed it so it’s just a little bit bigger than the (enlarged!) hole in the box.

Now the entrance is 1-¼ (-ish), just like it should be:

Bird Box - PVC pipe reducer - installed — Bird Box – PVC pipe reducer – installed

The bird box in the front yard has been attracting starlings, in addition to serving as a hawk perch:

New Coopers Hawks - bird box takeoff whoops — New Coopers Hawks – bird box takeoff whoops

The oblong hole required advanced manufacturing techniques:

The front face should be too slick for larger birds and the little ones will zip right into the hole:

Bird Box - 3D printed entrance reducer — Bird Box – 3D printed entrance reducer

The two starlings who’d been evaluating the box seem to have moved on; we doubt they’re now homeless.

The OpenSCAD source code as a GitHub Gist:

	// Bird Box – oval entrance reducer
	// Ed Nisley KE4ZNU 2020-02-12

	//- Extrusion parameters must match reality!
	// Print with 3 shells and 3 solid layers

	ThreadThick = 0.25;
	ThreadWidth = 0.40;

	HoleWindage = 0.2;

	function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

	Protrusion = 0.1; // make holes end cleanly

	inch = 25.4;

	//———————-
	// Dimensions

	EntranceID = 1.25 * inch;

	BoxHole = [1.5,2.25] * inch;
	BoxWall = 0.75 * inch;

	HoleOC = BoxHole.y – BoxHole.x;

	FlangeWidth = 5.0;
	FlangeThick = 5*ThreadThick;

	$fn = 12*4;

	//——————-
	// Build it

	difference() {
	union() {
	linear_extrude(height=BoxWall + FlangeThick)
	hull()
	for (j=[-1,1])
	translate([0,j*HoleOC/2])
	circle(d=BoxHole.x);
	linear_extrude(height=FlangeThick)
	hull()
	for (j=[-1,1])
	translate([0,j*HoleOC/2])
	circle(d=BoxHole.x + 2*FlangeWidth);
	}
	translate([0,0,-Protrusion])
	cylinder(d=EntranceID,h=2*BoxWall);
	}

view raw Oval Entrance Reducer.scad hosted with ❤ by GitHub

2020-02-19

Filament Spool Sidewall

A new spool of retina-burn orange PETG snagged when the takeup guide let the filament fall off the inboard side and the extruder tightened the loops around the spool holder. I carefully unwound the loops without removing the spool to ensure I didn’t introduce a crossover, scraped the bird’s next off the platform, and restarted the print.

After undoing the second snag, I added a crude spool sidewall:

Makergear M2 - filament spool sidewall — Makergear M2 – filament spool sidewall

It’s decidedly unlovely, but I was in a hurry to get a PCB holder printed and ready for use. Worked perfectly!

I’ve rarely had a problem with any other spools and I don’t know what’s new-and-different with this one.

2020-02-03

Photo Lamp Mount: Moah Plastic!

One of the cold shoe mounts I made for the photo lamps cracked:

Photo Lamp Mount - fractured — Photo Lamp Mount – fractured

It’s done in PETG with my more-or-less standard two perimeter threads and 15% 3D honeycomb infill, which is Good Enough™ for most of my parts. In this case, there’s obviously not nearly enough plastic in there!

Redoing it with three perimeters and 50% infill should improve the situation, even though it looks identical on the outside:

Photo Lamp Mount - reinstalled — Photo Lamp Mount – reinstalled

I didn’t replace the other mount. If it breaks, it’ll get the same 50% infill as this one. If this one breaks, I’ll try 75%.

An easy fix!

2020-01-19

Tag: M2

Fu Mask Cutting Templates

Round Soaker Hose Splint

HON Lateral File: Shelf Rebuild

Refrigerator Coil Wand Adapter Rebuild

Bird Box Entrance Reducers: Round 2

Filament Spool Sidewall

Photo Lamp Mount: Moah Plastic!