Tag: M2

Using and tweaking a Makergear M2 3D printer

Machine Shop, Software

Tailor’s Clapper: 3D Printed Finger Grips

With the pockets milled into the oak blocks, the next step is to insert a pair of comfy 3D printed finger grips:

Ironing weight - prototype grip
Ironing weight – prototype grip

Getting comfy required a bank shot off the familiar chord equation to find the radius of a much larger circle producing the proper depth between the known width. The recess then comes from subtracting a hotdog from a lozenge exactly filling the wood pocket.

Ironing Weight Finger Grip - recess chord
Ironing Weight Finger Grip – recess chord

A pair of grips takes just under two hours to print while requiring no attention, which I vastly prefer to tending the Sherline.

The wood pocket is 7 mm deep and the grips stand 6.5 mm tall, leaving just enough room for three blobs of acrylic adhesive to hold them together. After squishing the grips into their pockets, a pair of right angles aligned everything while the adhesive cured:

Ironing weight - grip adhesive curing
Ironing weight – grip adhesive curing

Mary asked for a longer weight for a place mat project, with a slightly narrower block to compensate for the additional length:

Ironing weight - seam ironing B
Ironing weight – seam ironing B

The grip and pocket were the same size, so it was just a matter of tweaking the block size and cutting more wood.

All in all, a quick project with satisfying results!

The OpenSCAD source code as a GitHub Gist:

// Oak ironing weight finger grips
// Ed Nisley KE4ZNU 2023-01
Layout = "Show"; // [Block,Grip,Show,Build]
//- Extrusion parameters must match reality!
/* [Hidden] */
ThreadThick = 0.25;
ThreadWidth = 0.40;
HoleWindage = 0.2;
Protrusion = 0.1; // make holes end cleanly
inch = 25.4;
function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);
ID = 0;
OD = 1;
LENGTH = 2;
//----------
// Dimensions
// Length along X axis
Block = [250.0,50.0,39.0]; // overall wood block
BlockRadius = 10.0;
CornerRadius = 10.0;
Kerf = 0.2;
Socket = [160.0,25.0,6.5]; // raw recess into block
SocketRadius = Socket.y/2;
echo(Socket=Socket,SocketRadius=SocketRadius);
WallThick = ThreadWidth; // Thinnest printed wall
Clearance = 0.5; // between grip and recess
GripBlock = Socket - [2*Clearance,2*Clearance,Clearance];
GripBlockRadius = SocketRadius - Clearance;
echo(GripBlock=GripBlock);
GripDepth = 5.0; // finger grip recess
GripRecess = [GripBlock.x - 2*WallThick,GripBlock.y - 2*WallThick,GripDepth];
GripRecessRadius = GripBlockRadius - WallThick;
echo(GripRecess=GripRecess,GripRecessRadius=GripRecessRadius);
GripChordRadius = (pow(GripDepth,2) + pow(GripRecess.y,2)/4) / (2*GripDepth);
echo(GripChordRadius=GripChordRadius);
NumSides = 4*8;
//----------
// Shapes
module WoodBlock() {
difference() {
hull()
for (i=[-1,1], j=[-1,1]) // rounded block
translate([i*(Block.x/2 - BlockRadius),j*(Block.y/2 - BlockRadius),-Block.z/2])
cylinder(r=BlockRadius,h=Block.z,$fn=NumSides);
for (j=[-1,1]) // grip socket
translate([0,j*(Block.y/2 + Protrusion),0])
rotate([j*90,0,0])
hull() {
for (i=[-1,1])
translate([i*(Socket.x/2 - SocketRadius),(Socket.y/2 - SocketRadius),0])
cylinder(r=SocketRadius,h=Socket.z + Protrusion,$fn=NumSides);
}
cube([2*Block.x,2*Block.y,Kerf],center=true);
}
}
module Grip() {
difference() {
hull()
for (i=[-1,1]) // overall grip block
translate([i*(GripBlock.x/2 - GripBlockRadius),0,0])
cylinder(r=GripBlockRadius,h=GripBlock.z,$fn=NumSides);
hull() {
for (i=[-1,1]) // grip recess
translate([i*(GripBlock.x/2 - GripRecessRadius - WallThick),
0,
GripChordRadius + GripBlock.z - GripDepth])
sphere(r=GripChordRadius,$fn=NumSides);
}
}
}
//----------
// Build them
if (Layout == "Block")
WoodBlock();
if (Layout == "Grip")
Grip();
if (Layout == "Show") {
color("Brown")
WoodBlock();
color("Silver")
for (j=[-1,1])
translate([0,j*(Block.y/2 - GripBlock.z),0])
rotate([j*-90,0,0])
Grip();
}
if (Layout == "Build") {
for (i=[-1,1])
translate([i*(Block.y/2 - GripBlock.z),0,0])
rotate([0,0,90])
Grip();
}
view raw Ironing Weight Finger Grip.scad hosted with ❤ by GitHub
Home Ec, Machine Shop, Software

Ironing Weight, a.k.a. Tailor’s Clapper: Overview

Mary wanted some ironing weights, formally known as tailor’s clappers, to produce flatter seams as she pieced fabric together:

Ironing weight - flattened seam
Ironing weight – flattened seam

The weights are blocks of dense, hard, unfinished wood:

Ironing weight - seam ironing A
Ironing weight – seam ironing A

One can buy commercial versions ranging from cheap Amazon blocks to exotic handmade creations, but a comfortable grip on a block sized to Mary’s hands were important. My lack of woodworking equipment constrained the project, but the picture shows what we settled on.

The general idea is a rounded wood block with 3D printed grips:

Ironing Weight Finger Grip
Ironing Weight Finger Grip

All other clappers seem to have a simple slot routed along the long sides, presumably using a round-end or ball cutter, which means the cutter determines the shape. This being the age of rapid prototyping, I decided to put the complex geometry in an easy-to-make printed part inserted into a simple CNC-milled pocket.

The first pass at the grip models:

Ironing Weight Finger Grip - slicer preview
Ironing Weight Finger Grip – slicer preview

Both recesses came from spheres sunk to their equators with their XY radii scaled appropriately, then hulled into the final shape. Customer feedback quickly reported uncomfortably abrupt edges along the top and bottom:

Ironing Weight - maple prototype
Ironing Weight – maple prototype

We also decided the straight-end design didn’t really matter, so all subsequent grips have rounded ends to simplify milling the pocket into the block.

With the goal in mind, the next few posts will describe the various pieces required to make a nice tailor’s clapper customized to fit the user’s hand.

Home Ec, Machine Shop, Science

Step2 Garden Seat: Seat3

Another tray becomes a replacement for the plywood on the Step2 rolling seat in the Vassar Farms plot:

Step2 Garden Seat - weathered plywood
Step2 Garden Seat – weathered plywood

I reused the old hinges, as this tray seems to be slightly thicker than the one on the home garden seat. The straight edges show it’s also somewhat smaller, but it’ll work just fine.

The bottom of the tray with its Silite logo now faces upward, because the top surface has eroded to a matte finish while supporting a bunch of plants outdoors during several summers:

Step2 Garden Seat - tray top
Step2 Garden Seat – tray top

So you can get two or three years from a painted plywood slab out in a garden, depending on how fussy you are about looks.

After two seasons, the first tray doesn’t look any the worse for wear: Silite trays really will survive the Apocalypse and be ready to serve breakfast the next day.

Machine Shop

Dripworks Mainline Puncture: In A Good Cause

Mary poked a garden fork tine into the mainline pipe of the garden irrigation plumbIng:

Mainline pipe puncture
Mainline pipe puncture

Fortunately, I have a pipe clamp for just such occasions:

Mainline pipe puncture - repaired - with cause
Mainline pipe puncture – repaired – with cause

After installing the clamp, we excavated the reddish lump just beyond it:

Mainline pipe puncture - excavated sweet potato
Mainline pipe puncture – excavated sweet potato

It’s a purple sweet potato, one of several that had escaped from their assigned plot, grown beyond the pipe, and burrowed under the path.

Her garden is as neat and tidy as a garden can be, but digging in the soil to find the crops isn’t an exact process!

Machine Shop, Recumbent Bicycling

Tour Easy: Another Front Fender Bracket

The mudflap on my front fender rides low enough to snag on obstacles and the most recent incident (about which more later) was a doozy, breaking the left strut ferrule and pulling the bracket off its double-sticky foam tape attachment. Fortunately, the repair kit now has plenty of duct tape.

The replacement printed up and installed just like its predecessors:

Tour Easy - front fender bracket
Tour Easy – front fender bracket

Having the bracket be the weakest link makes perfect sense to me …

Machine Shop

Laser Cutter: Sheet Holder

Applying a laser cutter to paper-like materials requires balancing two contradictory imperatives:

  • Hold the sheet flat to avoid distortions
  • Have nothing below to avoid schmutz on the bottom

This seemed like a good compromise:

Sheet Holder - Tek CC bottom deck
Sheet Holder – Tek CC bottom deck

The orange 3D printed blocks hold aluminum miniblind blades:

Sheet Holder - steel sheet magnet pads
Sheet Holder – steel sheet magnet pads

The curved slots hold the blades flush with the upper surface and align their top sides parallel to the laser beam, giving the beam very little blade to chew on near the focus point and allowing plenty of room below the sheet to dissipate cutting fumes.

The gold-ish squares are thin steel sheets covered with Kapton tape, painstakingly filed en masse from small snippets:

Sheet Holder - filed steel pads
Sheet Holder – filed steel pads

The first iteration used precisely laser-cut refrigerator magnet pieces, in the expectation a crappy rubber magnet would provide just enough attraction to let a neodymium magnets hold the paper flat, without risk of blood blisters between fingers and steel:

Sheet Holder - ferrite magnet pads
Sheet Holder – ferrite magnet pads

As expected, contact with the neo magnet completely wiped away the alternating pole magnetism in the rubber sheet, leaving a weakly attractive non-metallic surface. Alas, the rubber had too little attraction through a laminated sheet of paper, so I switched to real steel and risked the blisters.

Most of the blocks are narrow:

Sheet Holder Bracket - solid model
Sheet Holder Bracket – solid model

The four corners are wider:

Sheet Holder Bracket - wide - solid model
Sheet Holder Bracket – wide – solid model

They’re symmetric for simplicity, with recesses for the magnets / steel sheets on the top. The through-holes have recesses for M3 SHCS holding them to T-nuts in Makerbeam rails, with a slightly overhanging alignment ledge keeping them perpendicular to the rail.

The magnets come from an array of worn-out Philips Sonicare toothbrush heads:

Sheet Holder - magnet holders curing
Sheet Holder – magnet holders curing

They’re epoxied inside a two-piece mount, with the lower part laser-machined from 3 mm acrylic to put the two magnets in each assembly flush with the lower surface; the green area gets engraved 1 mm below the surface for the steel backing plate. The 1.5 mm upper frame fits around the plate and protrudes over the ends just enough for a fingernail grip:

Magnet Holder Cuts
Magnet Holder Cuts

The epoxy got a few drops of fuschia dye, because why not:

Sheet Holder - trimmed magnet holders
Sheet Holder – trimmed magnet holders

The garish trimmings came from slicing the meniscus around the lower part of the holder off while the epoxy was still flexy.

The holders must be flat for clearance under the focus pen:

Sheet Holder - focus probe clearance
Sheet Holder – focus probe clearance

Some experimentation suggests I can raise the pen by maybe 2 mm (with a corresponding increase in the Home Offset distance) , but the switch travel requires nearly all of the protruding brass-colored tip and there’s not much clearance under the nozzle at the trip point.

With all that in hand, it works fairly well:

Sheet Holder - Tek CC cutout
Sheet Holder – Tek CC cutout

The lower deck has very little margin for gripping, which is why the four corner blocks must be a bit wider than the others.

The lamInator tends to curl the sheets around their width, so most of the clamping force should be along the upper and lower edges to remove the curl at the ends. This requires turning the whole affair sideways and deploying more magnets, which is possible for the smaller middle and upper decks:

Sheet Holder - Tek CC middle deck
Sheet Holder – Tek CC middle deck

Protruding SHCS heads on the four corners snug up against the edge of the knife-edge bed opening for Good Enough™ angular alignment.

Plain paper (anything non-laminated) seems generally flat enough to require no more than the corner magnets.

It’s definitely better than the honeycomb surface for fume control!

The OpenSCAD source code as a GitHub Gist:

// Bracket for sheet holder
// Ed Nisley KE4ZNU 2022-09-09
Layout = "Show"; // [Show, Build, Blade]
/* [Hidden] */
ThreadThick = 0.25;
ThreadWidth = 0.40;
HoleWindage = 0.2;
Protrusion = 0.1; // make holes end cleanly
ID = 0;
OD = 1;
LENGTH = 2;
module PolyCyl(Dia,Height,ForceSides=0) { // based on nophead's polyholes
Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);
FixDia = Dia / cos(180/Sides);
cylinder(r=(FixDia + HoleWindage)/2,
h=Height,
$fn=Sides);
}
// Sizes
Magnet = [10,30,0.5]; // magnetic sheet size
//Magnet = [10,14,0.5];
MagnetRim = 1.0;
Screw = [3.0,5.5,3.0]; // SHCS OD=head LEN=head
MakerBeam = 10.0; // beam size, screw = half height
BeamRecess = 0.5; // slight overhang for alignment
BladeSlot = 0.15 * 4; // slot with plenty of clearance
BladeSocket = 5.0; // recess to hold miniblind
BladeWidth = 24.6; // miniblind width
BladeM = 1.6; // height of miniblind curve
BladeSides = 12*8;
BladeRadius = (pow(BladeM,2) + pow(BladeWidth,2)/4)/(2*BladeM);
BladeAngle = 2*asin(BladeWidth/(2*BladeRadius));
echo(BladeRadius = BladeRadius);
echo(BladeAngle = BladeAngle);
Block = [Magnet.x + 2*MagnetRim + ceil(BladeRadius*(1 - cos(BladeAngle)) + 2.0),
Magnet.y + 2*MagnetRim,
BladeRadius*sin(BladeAngle)];
echo(Block = Block);
// Cutter for spline recess
// approximately correct and good enough
module BladeRing() {
rotate([90,0,0])
translate([0,0,-BladeSocket])
linear_extrude(height=2*BladeSocket,convexity=2)
difference() {
circle(r=BladeRadius,$fn=BladeSides);
circle(r=BladeRadius - BladeSlot,$fn=BladeSides);
}
}
// Overall bracket
module Bracket() {
difference() {
translate([0,-Block.y/2,0])
cube(Block,center=false);
translate([Magnet.x/2 + MagnetRim,0,Block.z - Magnet.z/2 + Protrusion/2])
cube(Magnet + [0,0,Protrusion],center=true);
for (j=[-1,1])
translate([0,j*Block.y/2,MakerBeam/2 - Protrusion/2])
cube([3*Block.x,2*BeamRecess,MakerBeam + Protrusion],center=true);
for (j=[-1,1])
translate([Magnet.x + 2*MagnetRim + BladeRadius,j*Block.y/2,Block.z])
BladeRing();
for (j=[-1,1])
translate([Block.x - 2.0 - BladeSlot,j*Block.y/2,5*ThreadThick/2 - Protrusion/2])
cube([2*BladeSlot,2*BladeSocket,5*ThreadThick + Protrusion],center=true);
translate([MakerBeam/2,Block.y,MakerBeam/2])
rotate([90,0,0])
PolyCyl(Screw[ID],2*Block.y,6);
for (j=[-1,1])
translate([MakerBeam/2,j*(Block.y/2 - Screw[LENGTH] - 1.0),MakerBeam/2])
rotate([-j*90,0,0])
PolyCyl(Screw[OD] + HoleWindage,2*Block.y,6);
}
}
//----------
// Build it
if (Layout == "Blade")
BladeRing();
if (Layout == "Show")
Bracket();
if (Layout == "Build")
Bracket();
view raw Sheet Holder Bracket.scad hosted with ❤ by GitHub
Electronics Workbench, Machine Shop, Recumbent Bicycling

SJCAM M20: Another Battery Bites the Dust

A little more than two years after replacing its internal battery, the SJCAM M20 camera on my Tour Easy once again wouldn’t last to the end of the driveway if I forgot to turn on the external battery pack. This time around, the camera was so firmly jammed in the printed seat frame mount that I had to cut the mount apart.

Yup, that puppy is all swoll up:

SJCAM M20 swollen battery - side view
SJCAM M20 swollen battery – side view

Poor thing looks like a tiny pillow:

SJCAM M20 swollen battery - pouch
SJCAM M20 swollen battery – pouch

While I had it apart, I tried to clean / refurbish the button contacts on the top. Unfortunately, they’re pretty well buried in the camera frame and I was unwilling to dismantle the optics, remove the display, and gut the camera to find out if they were more accessible from the back surface:

SJCAM M20 - switch internals
SJCAM M20 – switch internals

While all that was going on, I ran off a new mount in white PETG:

SJCAM M20 - white case installed
SJCAM M20 – white case installed

I’m down to the last battery. The “4.35V” on the pillow indicates they’re special high-voltage lithium-polymer cells, so I can’t just drop a random lithium pouch cell in there and expect it to Just Work.

I think the “782633” is the cell size, so, if I were willing to have a few thousand on the shelf, a 552525 pouch might fit. The reduced capacity wouldn’t be a problem, as it must just keep the camera’s clock ticking between rides.

Drat!