MK4 – Page 2 – The Smell of Molten Projects in the Morning

HQ Sixteen: Fabric Rod Bearings

The rods (a.k.a. tubes or poles) holding & guiding the quilt top / batting / backing fabric on Mary’s HQ Sixteen longarm quilting machine span the eleven feet of the table:

HQ Sixteen - table overview — HQ Sixteen – table overview

The two end plates are 1/4 inch steel plate with four punched holes for the rods / tubes, which look remarkably like EMT. The machine is two decades old and Mary is (at least) the third owner, so it’s no surprise the rods long ago wore through the white powder-coat paint on the plates and, during the course of a long quilting project, now deposit black dust on the table.

Black dust not being tolerable near a quilt-in-progress, Mary asked for an improvement.

The tube OD is 28.7 mm (so it’s probably 1 inch EMT) and the plate hole ID is 31.2 mm (likely a scant 1-¼ inch punch), leaving barely a millimeter of clearance all around. I wanted to make a bearing from suitably slippery Delrin / acetal, but figured 3D printed PETG would suffice for at least while.

The proper term is “bushing“, because it has no moving parts:

Rod Bearing Sleeve - solid model - show view — Rod Bearing Sleeve – solid model – show view

On the right side, the bushing rim must fit between the sprockets and the plate:

HQ Sixteen rod - right front — HQ Sixteen rod – right front

The spring-loaded pin holding the tube in place (visible on the inside bottom) sets the maximum length:

HQ Sixteen rod - right outer — HQ Sixteen rod – right outer

The left side has none of that, so I made the bushings a little longer:

HQ Sixteen rod - left inner — HQ Sixteen rod – left inner

The left-side bushings will need a better design should normal back-and-forth sliding push them out of place.

A touch of silicone grease around the plate holes makes those bushings / bearings turn sooo smooth.

The OpenSCAD source code as a GitHub Gist:

	// Bearing sleeve for HQ Sixteen table rods
	// Ed Nisley – KE4ZNU
	// 2026-02-20

	include <BOSL2/std.scad>

	Layout = "Show"; // [Show,Build]

	/* [Hidden] */

	ID = 0;
	OD = 1;
	LENGTH = 2;

	HoleWindage = 0.2;
	Protrusion = 0.1;
	NumSides = 832*4;

	$fn=NumSides;

	Rod = [25.0,28.7,100.0]; // very short rod

	Sleeve = [Rod[OD] + 0.3,31.2 – 0.2,9.0]; // LENGTH = overall
	Rim = [Sleeve[ID],Sleeve[OD] + 6.0,0.6];

	IdlerLength = 15.0;

	NumSlots = 2*4;
	Kerf = 1.0;

	Gap = 5.0;

	module Bearing(oal) {

	difference() {
	union() {
	tube(oal,id=Sleeve[ID],od=Sleeve[OD],anchor=BOTTOM);
	tube(Rim[LENGTH],id=Rim[ID],od=Rim[OD],anchor=BOTTOM);
	}
	for (a=[0:NumSlots-1])
	zrot(a*360/NumSlots)
	up(oal/4 + Rim[LENGTH])
	right(Sleeve[ID]/2)
	cuboid([Sleeve[OD],Kerf,oal],anchor=BOTTOM);
	}

	}


	//—–
	// Build things

	if (Layout == "Show") {
	color("Gray",0.5)
	xcyl(Rod[LENGTH],d=Rod[OD]);
	right(Rod[LENGTH]/3)
	yrot(90)
	Bearing(Sleeve[LENGTH]);
	left(Rod[LENGTH]/3)
	yrot(90)
	Bearing(IdlerLength);
	}

	if (Layout == "Build") {
	right(Rim[OD]/2 + Gap/2)
	Bearing(Sleeve[LENGTH]);
	left(Rim[OD]/2 + Gap/2)
	Bearing(IdlerLength);


	}

view raw Rod Bearing Sleeve.scad hosted with ❤ by GitHub

2026-02-23

Work Sharp Precision Sharpener: Knob Lock

Having recently sharpened a small blade at a very low angle, I must put in a good word for the knob lock found on Printables:

WorkSharp - knob lock — WorkSharp – knob lock

The protrusion on the tab fits into the back side of the frame, but it works well enough in front, too.

Wearing cut-resistant gloves remain a good idea.

2026-02-18

Stick Blender Bearing Failure

The business end of a cheap stick blender we bought a year ago to replace the previous stick blender (*):

This one failed just slightly beyond the duration of its one-year warranty, apparently with one of the shaft bearings seized to the extent of making the blade un-turnable even by (carefully protected) finger force.

With nothing to lose (and a new blender inbound), it stood in the Basement Shop in that orientation for a week while I dripped penetrating oil around the shaft and wiggled the blade slightly back-and-forth. The bearing eventually broke free and the blade turned reluctantly.

Still having nothing to lose, I gave the shaft a few shots with a drift punch, moving it a few millimeters in each direction. This apparently disturbed the seized bearing just enough to let it turn less reluctantly, with more penetrating oil improving the situation.

Mixing a jar of water went well, even on high speed, but I doubt the bearing is in good health. We decided a blender with penetrating oil tucked up inside should be disqualified for food processing.

When it first locked up, I bought a significantly more expensive stick blender, knowing full well more money does not imply better design / better materials / more QC. This one is now designated as a Cold Backup blender for garden & shop use.

(*) For the record, my 3D printed shaft adapter failed while converting garden tomatoes into thick & zesty pizza sauce. I’m unsurprised PETG-CF wasn’t up to the task.

2026-02-13

Prusa MK4 Nozzle Tool Mod

Contemplating a 0.8 mm nozzle to print more-transparent things, I ran off an Official MK4 Nozzle Replacement Tool to stabilize the heater block while applying a wrench to the nozzle:

Prusa MK4 Nextruder Tool - without inlet scoop — Prusa MK4 Nextruder Tool – without inlet scoop

For obvious reasons, it doesn’t fit with the inlet scoop I installed as part of blinging the MK4:

Prusa MK4 Nextruder Tool - inlet scoop installed — Prusa MK4 Nextruder Tool – inlet scoop installed

Removing the scoop is a matter of removing those two cap screws, which is no big deal, but a little flush-cutter action made that problem Go Away forever:

Prusa MK4 Nextruder Tool - inlet scoop mod — Prusa MK4 Nextruder Tool – inlet scoop mod

Yeah, I should have modified the solid model. Maybe next time.

A version of the tool fits extruders covered with an Official Prusa Silicone Sock thermal insulator, but they were out of stock when I was in the mood. My heater wears a knockoff sock:

Prusa MK4 Nextruder Tool - silicone sock vs nozzle — Prusa MK4 Nextruder Tool – silicone sock vs nozzle

Unlike the Official Sock, there’s no way to get a wrench on the nozzle with that one installed, but removing the sock is no big deal.

I apparently installed the nozzle / heater block slightly higher than specified, so the tool didn’t quite fit. Loosening those two thumbscrews and lowering the nozzle to fit the tool solved that problem. Fortunately, the automatic bed leveling routine corrects for nozzle height differences on the fly.

The scoop is back on the fan, the sock once again surrounds the heater, and I can easily swap in the 0.8 mm nozzle when the time comes.

2026-01-21

Olive Oil Bottle Cap Covers

We buy olive oil in large bottles, then fill smaller bottles for easier handling. The caps on those bottles were never meant to last as long as we keep them and the thin, deeply drawn aluminum tends to crack after a while.

So I conjured a cap cover from the vasty digital deep:

Olive Oil Cap - solid model — Olive Oil Cap – solid model

Which looks exactly like you’d expect when printed in black PETG:

Olive oil bottle cap - details — Olive oil bottle cap – details

You can see the raggedy edge of the original cap just inside the cover’s rim. A snippet of double-sided tape holds the cover in place, after de-oiling the cap with alcohol.

Having gotten one to fit, I made enough for All The Bottles:

Olive oil bottle cap - installed — Olive oil bottle cap – installed

Only two of those see regular service: one in use and another filled when the first is nearly empty. The remaining pair huddle in the back of the shelf against future need.

The OpenSCAD source code produces those fancy knurls with BOSL2’s textured cyl() :

// Shower soap dish
// Ed Nisley - KE4ZNU
// 2026-01-17

include <BOSL2/std.scad>

/* [Hidden] */

HoleWindage = 0.2;
Protrusion = 0.1;
NumSides = 5*3*4;

$fn=NumSides;

ID = 0;
OD = 1;
LENGTH = 2;

WallThick = 1.0;
BaseThick = 2.0;

CapOD = 36.0;

CoverOA = [CapOD,CapOD + 2*WallThick,20.0 + BaseThick];

//----------
// Build it

  render()
    difference() {
      cyl(BaseThick,d=CoverOA[OD],chamfer1=1.0,anchor=BOTTOM) position(TOP)
        cyl(CoverOA[LENGTH] - BaseThick,d=CoverOA[OD],
            texture="trunc_pyramids",tex_size=[2,6], style="convex",
            anchor=BOTTOM);
      up(BaseThick)
        cyl(CoverOA[LENGTH],d=CoverOA[ID],anchor=BOTTOM);
    }

2026-01-20

Translucent Night Light Light Guide

Our house came with several single-LED night lights featuring a transparent light guide / reflector:

Nightlight light guide - original — Nightlight light guide – original

The plate had snapped off one of them and, being me, I wondered if I could replace it with something similar.

Years passed.

Obviously, this must be made from a transparent substance, which 3D printed things are not, but after some fiddling with parameters I thought the result might be informative.

The guide plate is a section of a spherical surface, here approximated by a BOSL2 spheroid():

Nightlight light guide - view side - solid model — Nightlight light guide – view side – solid model

The original is 3 mm thick, but 2 mm worked out better for my purposes by reducing the amount of infill:

Nightlight light guide - wall side - solid model — Nightlight light guide – wall side – solid model

The intricate base latches into the lamp’s plastic case:

Nightlight light guide - base - solid model — Nightlight light guide – base – solid model

The result is, at best, translucent, because it’s definitely not transparent:

Nightlight light guide - translucent vs transparent — Nightlight light guide – translucent vs transparent

The zigzag pattern seems to come from the icosohedral approximation to the sphere, because it follows the surface tesselation.

Getting the base shape right required several iterations, each printed with the model cut off just above the bottom of the guide plate:

Nightlight light guide - test pieces — Nightlight light guide – test pieces

The first two attempts needed attention from a flush cutting pliers before fitting into the case, but they don’t call it rapid prototyping for nothin’.

The original and replacement plugged into an outlet strip:

Nightlight light guide - original vs printed on outlet strip — Nightlight light guide – original vs printed on outlet strip

While you can see the vague outline of the strip behind the printed light guide, it’s definitely lacking in detail:

Nightlight light guide - outlet strip detail — Nightlight light guide – outlet strip detail

The striations throw more light into the room than the original:

Nightlight light guide - printed — Nightlight light guide – printed

Fiddling with the 3D printing parameters might make it more transparent, but it’s going back into the box it came from after giving me a better idea of which parameters to tweak the next time around.

The OpenSCAD source code as a GitHub Gist:

	// Nightlight light guide
	// Ed Nisley – KE4ZNU
	// 2026-01-13

	include <BOSL2/std.scad>

	Layout = "Show"; // [Show,Build,Plate,Base,Pipe]

	/* [Hidden] */

	HoleWindage = 0.2;
	Protrusion = 0.1;
	NumSides = 1034;

	$fn=NumSides;

	ID = 0;
	OD = 1;
	LENGTH = 2;

	function ChordRadius(m,c) = (m^2 + (c^2)/4) / (2*m);

	PlateThick = 2.0;
	PlateOA = [60.0,50.0,PlateThick];
	PlateRound = 5.0;
	PlateTaper = 1.0;
	PlateAngle = atan(-2/60); // original plate angle, far end closer to wall

	PlateM = 2.4;
	PlateRadius = ChordRadius(PlateM,PlateOA.x); // light guide plate
	echo(PlateRadius=PlateRadius);

	WallThick = 2.0;

	MountOA = [23.4,17.0,5.5];
	MountRadius = ChordRadius(4.3,MountOA.x); // base arc in housing
	echo(MountRadius=MountRadius);

	PipeThick = 5.0;

	//———-
	// Define shapes

	// Oddly intricate base fitting into housing
	// Replete with magic numbers

	module Base() {

	difference() {
	union() {
	intersection() {
	cuboid([MountOA.x,MountOA.y,5.5],anchor=BOTTOM);
	back(6.5)
	tube(MountOA.z,or=MountRadius,wall=1.5,anchor=BOTTOM+BACK);
	}

	for (i=[-1,1])
	right(i*18.5/2)
	back(11.5)
	cuboid([1.8,8.0,MountOA.z],anchor=BOTTOM+BACK);

	for (i=[-1,1])
	right(i*22.0/2)
	cuboid([1.4,2.0,MountOA.z],anchor=BOTTOM+FRONT);

	fwd(5.0)
	cuboid([11.0,10.5,MountOA.z],anchor=BOTTOM+FRONT);
	}

	down(Protrusion)
	for (j=[-1,1])
	fwd(j*(1.5 + 10.0)/2)
	cuboid([7.0,10.0,MountOA.z + 2*Protrusion],anchor=BOTTOM);

	up(3.1)
	back(7.5)
	cuboid([MountOA.x,25.0,MountOA.z],anchor=BOTTOM+FRONT);
	}
	}

	// Light guide plate

	module Plate() {

	xrot(PlateAngle)
	zrot(90) yrot(90)
	left(PlateOA.x/2)
	down(PlateM + PlateThick/2)
	intersection() {
	up(PlateRadius)
	difference() {
	spheroid(PlateRadius,style="icosa");
	spheroid(PlateRadius – PlateThick,style="icosa");
	}
	cuboid(PlateOA + [0,0,2*PlateThick],rounding=PlateRound,edges="Z",anchor=BOTTOM);
	}

	}

	// Light pipe between base & plate
	// Magic numbers to fit case opening

	module Pipe() {

	difference() {
	intersection() {
	fwd(3.0/2 – 0.2)
	cuboid([MountOA.x,MountOA.y,PipeThick],rounding=0.5,edges="Z",anchor=BOTTOM+FRONT);
	back(6.5)
	cyl(MountOA.z,r=MountRadius,anchor=BOTTOM+BACK);
	}

	down(Protrusion)
	back((1.5 + 10.0)/2)
	cuboid([7.0,10.0,1.0 + Protrusion],anchor=BOTTOM);

	}

	}

	module Assembly() {

	Base();

	up(MountOA.z)
	Pipe();

	up(MountOA.z + PipeThick)
	Plate();
	}


	//———-
	// Build things

	if (Layout == "Base")
	Base();

	if (Layout == "Plate")
	Plate();

	if (Layout == "Pipe")
	Pipe();

	if (Layout == "Show" \|\| Layout == "Build")
	Assembly();

view raw Nightlight Light Guide.scad hosted with ❤ by GitHub

2026-01-16

Translucent Soap Dishes

A SquidWrench meeting discussion about printing transparent objects prompted me to conjure a soap dish from the vasty digital deep:

Shower Soap Dish - solid model — Shower Soap Dish – solid model

They’re all done in “natural” PETG with sufficient variations in speed, temperature, extrusion multiplier, and fill pattern to stock the shower & tub:

The single-thread sidewalls came out reasonably translucent in all the variations, but the baseplate remained stubbornly white-ish, even at 20 mm/s and 250 °C with 100% infill. The seams where the extruder retracts and lifts to the next layer remain conspicuous, with a scarf joint forming the white slab in the left-rear dish.

Quite a while ago, I’d considered making soap dishes with shattered-glass bottoms, but came to my senses. These have some key advantages:

Exactly the right size for narrow shower shelves
Light enough to not damage anything when it inevitably falls off
Reasonably unbreakable when that happens
Easily replaced

They’re also test pieces for the whole transparency thing, so it’s all good.

The OpenSCAD source code as a GitHub Gist:

	// Shower soap dish
	// Ed Nisley – KE4ZNU
	// 2026-01-13

	include <BOSL2/std.scad>

	/* [Hidden] */

	HoleWindage = 0.2;
	Protrusion = 0.1;
	NumSides = 334;

	$fn=NumSides;

	ID = 0;
	OD = 1;
	LENGTH = 2;

	WallThick = 0.6;
	BaseThick = 2.0;

	//DishOA = [80.0,40.0,20.0]; // standing used Dove
	DishOA = [90.0,50.0,30.0]; // standing Dove
	//DishOA = [100.0,65.0,30.0]; // half-bar

	DishTaper = [10.0,10.0];
	CornerRadius = 15.0;

	DrainOA = [10.0,DishOA.y,3.0];
	DrainOC = DishOA.x/3;

	//———-
	// Build it

	difference() {
	union() {
	linear_extrude(BaseThick)
	rect([DishOA.x,DishOA.y] – DishTaper,rounding=CornerRadius);

	rect_tube(DishOA.z,wall=WallThick,
	size1=[DishOA.x,DishOA.y] – DishTaper,size2=[DishOA.x,DishOA.y],
	rounding=CornerRadius,anchor=BOTTOM);
	}

	for (j=[-1,1])
	right(j*DrainOC/2)
	up(BaseThick)
	cuboid(DrainOA,rounding=1.0,anchor=BOTTOM+BACK);
	}

view raw Shower Soap Dish.scad hosted with ❤ by GitHub

2026-01-15

Tag: MK4

HQ Sixteen: Fabric Rod Bearings

Work Sharp Precision Sharpener: Knob Lock

Stick Blender Bearing Failure

Prusa MK4 Nozzle Tool Mod

Olive Oil Bottle Cap Covers

Translucent Night Light Light Guide

Translucent Soap Dishes