Software – Page 6 – The Smell of Molten Projects in the Morning

3D Printed 20×102mm Cartridge

Having accumulated a box of empty 12 gram CO₂ capsules and having already done Too Many bomb fins:

The capsule is obviously the wrong shape, too short, and only 19 mm diameter, but it’s the thought that counts.

Apply the contour gauge to a genuine slightly battered 20×102mm cartridge:

Scan the sketch, import into Inkscape, rotate the image to correct the case taper angle vs. the page, lay lines & curves around the perimeter, align half of it at the page origin to work with OpenSCAD, export as SVG:

Cartridge - 20x102mm outline - Inkscape layout — Cartridge – 20x102mm outline – Inkscape layout

Import into OpenSCAD, let rotate_extrude do the heavy lifting, and remove some pieces:

Cartridge Case - build view solid model — Cartridge Case – build view solid model

The little disk represents a fired primer you’d print separately in a different color and glue into the pocket shown in this cutaway view:

Cartridge Case - cutaway solid model — Cartridge Case – cutaway solid model

The interior void could hold sand for additional heft, as the whole thing is obviously nose-heavy; that’s certainly in the nature of fine tuning. Obviously, we are not dealing with anything that could go bang.

It builds just like you’d expect:

20x102mm cartridge - printing — 20x102mm cartridge – printing

Dab some adhesive on the capsule tip, ditto for the primer, stick them in place, and it’s all good.

I like the gray PETG-CF version:

20x102mm cartridges - blue gray PETG-CF — 20x102mm cartridges – blue gray PETG-CF

Maybe not such a good idea in this day & age. Print responsibly, as they say.

Update

Print a sabot to fit a CO₂ capsule into a genuine steel cartridge.

The solid model:

Cartridge Case - sabot solid model — Cartridge Case – sabot solid model

The OpenSCAD making it happen:

module Sabot() {
tube(SabotOA[LENGTH],id=SabotOA[ID],od=SabotOA[OD],anchor=BOTTOM)
    position(BOTTOM)
      tube(SabotOA[LENGTH]/2,id=SabotOA[ID],od=CartridgeOA[ID],anchor=BOTTOM);
}

The result:

The OpenSCAD source code (minus the sabot) and outline as a GitHub Gist:

Sorry, something went wrong. Reload?

Sorry, we cannot display this file.

Sorry, this file is invalid so it cannot be displayed.

view raw Cartridge – 20x102mm outline.svg hosted with ❤ by GitHub

	// 20x102mm cartridge
	// Ed Nisley – KE4ZNU
	// 2025-05-18

	include <BOSL2/std.scad>

	Layout = "Show"; // [Show,Build]

	Powder = true; // build internal void

	/* [Hidden] */

	ID = 0;
	OD = 1;
	LENGTH = 2;

	HoleWindage = 0.2;
	Protrusion = 0.1;
	NumSides = 334;

	$fn = NumSides;

	CartridgeOA = [21.0,29.5,101.4]; // must match SVG pretty closely

	PrimerOA = [2.0,8.0,2.0];

	CapsuleTip = [7.5,7.5,5.0];
	Capsule = [7.5,18.8 + HoleWindage,83];
	SeatingDepth = 25.0;

	Void = [CartridgeOA[ID]- 4.0,CartridgeOA[OD]- 4.0,CartridgeOA[LENGTH] – SeatingDepth – 4*PrimerOA[LENGTH]];

	//———-
	// Define shapes

	module Cartridge() {

	difference() {
	rotate_extrude()
	import("Cartridge – 20x102mm outline.svg",layer="Cartridge Aligned Half");
	up(PrimerOA[LENGTH])
	cyl(PrimerOA[LENGTH] + Protrusion,d=PrimerOA[OD],anchor=TOP);
	up(CartridgeOA[LENGTH] + CapsuleTip[LENGTH])
	cyl(SeatingDepth,d=Capsule[OD],anchor=TOP);
	up(CartridgeOA[LENGTH] – SeatingDepth)
	cyl(Void[LENGTH],d=CapsuleTip[OD],anchor=BOTTOM);
	if (Powder) {
	up(Void[LENGTH]/2)
	cyl(Void[LENGTH],d=CapsuleTip[OD],anchor=BOTTOM);
	up(2*PrimerOA[LENGTH])
	cyl(Void[LENGTH],d=Void[OD],rounding=Void[OD]/2,anchor=BOTTOM);
	down(Protrusion)
	cyl(Void[LENGTH],d=PrimerOA[ID],anchor=BOTTOM);
	}
	}

	}

	module Primer() {
	difference() {
	cyl(PrimerOA[LENGTH] – Protrusion,d=PrimerOA[OD] – HoleWindage,anchor=BOTTOM);
	up(PrimerOA[LENGTH])
	spheroid(d=PrimerOA[ID]);
	}
	}


	//———-
	// Build things

	if (Layout == "Show")
	//render()
	difference() {
	Cartridge();
	cuboid(3*CartridgeOA[LENGTH],anchor=LEFT+BACK);
	}

	if (Layout == "Build") {
	Cartridge();
	right(CartridgeOA[OD])
	Primer();
	}

view raw Cartridge 20x102mm.scad hosted with ❤ by GitHub

2025-05-20

Polymaker PolyDryer Box: PC4 Fitting Adapter

Having recently replaced the MMU3’s filament buffer with Polymaker PolyDryer boxes and auto-rewind spindles:

PolyDryer PC4 Fitting - Prusa MMU3 setup — PolyDryer PC4 Fitting – Prusa MMU3 setup

Their rubbery port covers work best with 6 mm OD PTFE tubes, but let the MMU3’s 4 mm tubes slide into / out of the boxes under normal filament extrusion / retraction forces, so I conjured an adapter for PC4-M10 pneumatic fittings:

PolyDryer PC4 Fitting - installed — PolyDryer PC4 Fitting – installed

A pair of M3 screws hold the adapter plate in place, with an EVA foam gasket sealing against the cover:

PolyDryer PC4 Fitting - interior view — PolyDryer PC4 Fitting – interior view

The PC4-M10 fittings let the 4 mm tubing slide right through, so the adapter has a 0.5 mm bottom sheet to block the tube, with a small hole for the filament:

PC4 Fitting Plates - bottom - solid model — PC4 Fitting Plates – bottom – solid model

You could use PC4-M6 fittings to block the tubing, but the 2 mm lumen on the fittings I have barely pass 1.75 mm nominal filament. Comments found elsewhere suggest identical PC4-M6 fittings have smaller lumens that snag the filament as it moves in one direction or the other.

The two blind holes get heat-staked 4×4mm M3 brass inserts.

The top has a threaded hole for the fitting:

PC4 Fitting Plates - top - solid model — PC4 Fitting Plates – top – solid model

Despite what the description says, the thread is not an M10 metric straight thread: it is a tapered pipe thread used for gas- and liquid-tight fittings. Considerable measurement & searching suggested a ⅛BSP-28 thread, because:

British Standard Pipe threads are used everywhere in the world except the USA
Both my metric tap sets have a ⅛BSP-28 tap along with all their hard-metric straight taps

The thread is painfully close to ⅛NPT-27, which would probably work in a pinch if it was the only tap you had.

Those PC4-M6 fittings might sport 1/16BSP-28 threads, but you’re on your own.

Further searching suggests nobody uses the corresponding tapered female pipe threads and everybody goes with a straight internal thread, so I conjured a stumpy threaded rod using the BOSL2 library and removed it from the adapter plate:

      threaded_rod(d=9.7,l=ThreadLength + Protrusion,pitch=INCH/28,internal=true,bevel2=true,anchor=BOTTOM);

The 9.7 mm diameter is the ⅛BSP-28 “major diameter”, rather than its “gauge diameter”, simply because it produced a good fit. The beveled top guides the fitting into the hole, but I still managed to cross-thread one.

The OpenSCAD code also produces SVG files to laser-cut the foam gasket and a drill template:

PolyDryer PC4 Fitting - drill template — PolyDryer PC4 Fitting – drill template

The holes were step-drilled to ⅛ inch (which has a historic relation to the ⅛BSP-28 size, because iron pipe) for a generous fit around the M3 screws.

That was way more complicated than I expected and I’m really glad to live in the future where this is a 3D printer project, not a metalworking project involving an actual tap in, say, steel.

The OpenSCAD source code as a GitHub Gist:

	// PC4 Fitting Plates for PolyDryer
	// Ed Nisley – KE4ZNU
	// 2025-05-02

	include <BOSL2/std.scad>
	include <BOSL2/threading.scad>

	Layout = "Plate"; // [Plate,Gasket,DrillGuide]

	/* [Hidden] */

	HoleWindage = 0.2;
	Protrusion = 0.1;
	NumSides = 334;

	Gap = 5.0;

	TubeStop = 0.5; // prevent PTFE tube from sliding through
	ThreadLength = 6.0;

	PlateOA = [28.0,22.0,ThreadLength + TubeStop];

	ScrewOC = 20.0;

	$fn=434;

	//———-
	// Define it

	module Plate() {

	difference() {
	cuboid(PlateOA,anchor=BOTTOM,rounding=4.0,edges="Z"); // plate to fit PolyDryer
	up(TubeStop) // thread for fitting
	threaded_rod(d=9.7,l=ThreadLength + Protrusion,pitch=INCH/28,internal=true,bevel2=true,anchor=BOTTOM);
	down(Protrusion)
	for (i = [-1,1])
	right(i*ScrewOC/2)
	cylinder(4.5 + TubeStop + Protrusion,d=3.7,anchor=BOTTOM); // M3 4×4 inserts
	down(Protrusion)
	cylinder(2*TubeStop,d=2.5,anchor=BOTTOM); // filament clearance
	}

	}

	//———-
	// Build things

	if (Layout == "Plate")
	Plate();

	if (Layout == "Gasket")
	projection(cut=true)
	Plate();

	if (Layout == "DrillGuide")
	difference() {
	projection(cut=true)
	Plate();
	circle(d=10);
	}

view raw PC4 Fitting Plates.scad hosted with ❤ by GitHub

2025-05-13

Anker LC-40 Flashlight Switch Repair

The switch on the Anker LC-40 flashlight serving as a running light on my Tour Easy became slightly intermittent before I replaced it with a 1 W amber LED, but it was still good enough to become the troubleshooting flashlight in the tray next to the Prusa Mk 4 printer. Eventually, of course, it failed completely and Something Had To Be Done.

Although I knew an exact replacement switch had to be available from the usual sources, I could not come up with a set of keywords capable of pulling them out of the chaff.

That was not a problem, because the assortment of SMD switches I used to replace the handlebar control caps on Mary’s Handi-Quilter HQ Sixteen contained push-on / push-off switches that were almost the right size:

Anker LC-40 Flashlight - switches and caps — Anker LC-40 Flashlight – switches and caps

Having recently convinced the MakerGear M2 3D printer to use TPU filament, all I had to do was produce a suitable cap to fit over the new switch in the flashlight’s tail:

Anker LC-40 Flashlight Button - TPU PrusaSlicer — Anker LC-40 Flashlight Button – TPU PrusaSlicer

Which turned into a multi-dimensional search over cap geometry, TPU extrusion speeds & feeds, and various impossible-to-directly-measure sizes:

Anker LC-40 Flashlight - TPU cap iterations — Anker LC-40 Flashlight – TPU cap iterations

The squarish block over on the left is PrusaSlicer’s version of a support structure wrapped around the first cap version; if human lives depended on it, I could surely extract the cap, but it would take a while.

The remaining ~~debris~~ samples occured while discovering:

An extruder temperature of 230 °C, not 250 °C, works well
A conical shape of the lip around the open end to eliminate the support structure
TPU doesn’t bridge well, so the closed end must be down
Length of the central pillar to barely touch the switch stem when released
Cap length and wall thickness so the TPU shell can collapse enough to actuate and release the switch stem
And so on and so on and scooby dooby dooby

Eventually I came up with a suitable combination:

Anker LC-40 Flashlight - switch caps — Anker LC-40 Flashlight – switch caps

Because I expected this would be an easy job, I used snap ring pliers to unscrew and rescrew the threaded retaining ring holding the switch PCB in place. Because the pliers didn’t have a stable grip on the ring, the threads eventually became just a bit goobered.

This was not a problem, because I have a(nother) 3D printer:

Anker LC-40 Flashlight Retainer - show view — Anker LC-40 Flashlight Retainer – show view

The gray thing on the right is a simple pin wrench fitting both the original and the replacement retaining rings, so I can orient the rings properly while unscrewing & rescrewing:

Anker LC-40 Flashlight - pin wrench in place — Anker LC-40 Flashlight – pin wrench in place

The threads have a 0.75 mm pitch and, while it’s possible to print screw threads, even a tedious 0.1 mm layer height would define each turn of the thread with only 7-½ layers.

This was not a problem, because I have a mini-lathe:

Anker LC-40 Flashlight - thread cutting — Anker LC-40 Flashlight – thread cutting

The yellow & green things on the left of those solid models are the fixture holding a retaining ring for threading and the washer applying pressure to keep the ring in place:

Anker LC-40 Flashlight - lathe fixture - detail — Anker LC-40 Flashlight – lathe fixture – detail

The alert reader will note that washer lacks holes for the alignment pins I added after seeing the washer sit not quite concentric on the fixture. I could call it continuous product improvement, although I doubt I’ll print another one.

Setting up the lathe involved finding the proper set of change gears, including the vital 42-50 stacked gear I made a while ago to print metric threads on a hard-inch lathe:

Anker LC-40 Flashlight - lathe change gear train — Anker LC-40 Flashlight – lathe change gear train

Although you’re supposed to measure the thread spacing on a skim pass, I find it’s easier to just measure the carriage movement for one spindle rotation:

Anker LC-40 Flashlight - lathe gear check — Anker LC-40 Flashlight – lathe gear check

A few passes produced a fine retaining ring:

Anker LC-40 Flashlight - pin wrench - detail — Anker LC-40 Flashlight – OEM vs lathe-cut threads

Sporting much nicer looking threads than the goobered original:

Anker LC-40 Flashlight - OEM vs lathe-cut threads — Anker LC-40 Flashlight – OEM vs lathe-cut threads

The original switch had a stabilizing ring around the body to prevent it from wobbling under the original rubber cap.

This was not a problem, because I have a laser cutter:

Anker LC-40 Flashlight - new switch in stabilizer — Anker LC-40 Flashlight – new switch in stabilizer

Those came from a scrap of fluorescent acrylic.

The wave washer behind the acrylic stabilizer improves the contact between the PCB trace around the rim and the flashlight tailcap, with the current passing through the body to the “light engine” up front. The retaining ring provides enough pressure to compress the wave washer, which is why it’s so easily goobered without a close-fitting pin wrench.

With everything assembled in reverse order, the flashlight worked pretty much as it did back when it was new:

Anker LC-40 Flashlight - TPU cap installed — Anker LC-40 Flashlight – TPU cap installed

However, after describing this during a recent SquidWrench meeting, I discovered that adding “latching” to my keywords surfaced a bodacious assortment of flashlight switches, so (a few days later) I removed the not-quite-right switch and replaced it with an identical twin of the OEM switch requiring just a little lead forming to fit the PCB.

Even better, using the 3D printed pin wrench to screw the original retaining ring into the flashlight’s aluminum threads a few times re-formed (unrelated to recent electrolytic capacitor reforming) its goobered threads well enough to fit and work perfectly again.

So I have:

… reassembled the flashlight with more-or-less original components
… a repair tool kit ready when another LC-40 fails
… re-learned the lesson that any time spent making a fixture or a special tool is not deducted from one’s allotment

And I loves me a happy ending or two!

The OpenSCAD source code as a GitHub Gist:

	// Anker LC-40 flashlight switch retainer
	// Ed Nisley – KE4ZNU
	// 2025-05-05

	include <BOSL2/std.scad>

	Layout = "Show"; // [Show,Build,Retainer,Fixture,Washer,Wrench]

	Gap = 5; // [0:10]

	/* [Hidden] */

	HoleWindage = 0.2;
	Protrusion = 0.1;
	NumSides = 334;

	ID = 0;
	OD = 1;
	LENGTH = 2;

	$fn=334;

	Plate = [16.8,20.0,3.0]; // retainer plate, OD allows for lathe threading
	PlateRecessDepth = 1.6;
	PlateInnerThick = Plate[LENGTH] – PlateRecessDepth;
	ClearID = 11.0;

	PinOD = 3.0;
	PinOC = 12.0;

	WrenchLength = 25.0; // handle on wrench
	JawLength = 22.0; // lathe jaw
	ThreaderOverrun = 10.0; // stick-out for threading tool clearance
	ThreadAllowance = 2*1.0; // clearance for thread depth

	//———-
	// Define Shapes

	module Retainer() {

	difference() {
	tube(Plate[LENGTH],od=Plate[OD],id=ClearID,anchor=BOTTOM);
	up(Plate[LENGTH] + Protrusion)
	cyl(PlateRecessDepth + Protrusion,d=Plate[ID],anchor=TOP);
	down(Protrusion)
	hull()
	for (i = [-1,1])
	right(i*PinOC/2) down(Protrusion)
	cyl(Plate[LENGTH] + Protrusion,d=PinOD,anchor=BOTTOM);
	}

	}

	module Fixture() {

	difference() {
	regular_prism(6,h=JawLength,d=1.2*Plate[OD],anchor=BOTTOM) position(TOP) {
	cyl(PlateRecessDepth + ThreaderOverrun,d=Plate[ID],anchor=BOTTOM);
	cyl(Plate[LENGTH] + ThreaderOverrun,d=ClearID,anchor=BOTTOM);
	// hull()
	for (i = [-1,1])
	right(i*PinOC/2)
	cyl(Plate[LENGTH] + ThreaderOverrun + Plate[LENGTH]/2,d=PinOD,anchor=BOTTOM);
	cyl(ThreaderOverrun,d=Plate[OD] – ThreadAllowance,anchor=BOTTOM);
	}
	up(JawLength + ThreaderOverrun + Plate[LENGTH] + Protrusion) // M4 burly insert
	cyl(10.0 + 5,d=5.5,anchor=TOP);
	}
	}

	module Washer() {

	difference() {
	tube(Plate[LENGTH],od=Plate[OD] – ThreadAllowance,id=4.5,anchor=BOTTOM);
	down(Protrusion)
	for (i = [-1,1])
	right(i*PinOC/2)
	cyl(2*Plate[LENGTH],d=PinOD,anchor=BOTTOM);
	}
	}

	module Wrench() {

	difference() {
	union() {
	cyl(WrenchLength,d=Plate[ID],anchor=BOTTOM);
	for (i = [-1,1])
	right(i*PinOC/2)
	cyl(WrenchLength + Plate[LENGTH],d=PinOD,anchor=BOTTOM);
	}
	down(Protrusion)
	cyl(2*WrenchLength,d=ClearID – 2.0,anchor=BOTTOM);
	}
	}

	//———-
	// Build things

	if (Layout == "Retainer")
	Retainer();

	if (Layout == "Fixture")
	Fixture();

	if (Layout == "Washer")
	Washer();

	if (Layout == "Wrench")
	Wrench();

	if (Layout == "Show") {
	color("Gold")
	Fixture();
	up(JawLength + ThreaderOverrun + Gap)
	zflip(z=Plate[LENGTH]/2)
	Retainer();
	color("Green")
	up(JawLength + ThreaderOverrun + Plate[LENGTH] + 2*Gap)
	Washer();

	right(40) {
	zflip(z=Plate[LENGTH]/2)
	Retainer();
	color("Silver")
	up(Plate[LENGTH] + Gap)
	zflip(z=WrenchLength/2)
	Wrench();
	}
	}

	if (Layout == "Build") {
	Fixture();
	right(1.5*Plate[OD]) {
	Retainer();
	fwd(1.5*Plate[OD])
	Retainer();
	}
	left(1.5*Plate[OD])
	Washer();
	fwd(1.5*Plate[OD])
	Wrench();
	}

view raw Anker LC-40 Flashlight Retainer.scad hosted with ❤ by GitHub

2025-05-12

Delta Shower Head Holder Extension

The original shower head being too far overhead for Mary’s reach, I installed a Delta ProClean Shower Head which would also be too high. It has a hose, which means I can adjust the height:

The InterWebs offer several 3D-printable versions of such a thing, but Delta offers many different shower heads, some of which are visually (to my eyes, anyway) indistinguishable from the 75740SN you see here. The model I tried did not fit the holder I have, so I conjured one from the vasty digital deep:

Delta shower head holder extension - solid model — Delta shower head holder extension – solid model

It builds standing on that tidy cutoff:

Delta shower head holder extension - PrusaSlicer warning — Delta shower head holder extension – PrusaSlicer warning

Despite PrusaSlicer’s kvetching about the “collapsing overhang” inside the socket, it came out fine.

The shower head is still slightly too high for her, but now I can print another one with a longer offset and a slightly smaller plug to fit deeper in the OEM socket.

Worst case, there’s a wall-mounted holder to put the shower head at shoulder height.

The OpenSCAD source code as a GitHub Gist:

	// Delta shower head holder extension
	// Ed Nisley – KE4ZNU
	// 2025-05-02

	include <BOSL2/std.scad>

	Layout = "Show"; // [Show,Build,Plug,Socket,Connector]

	MountAngle = 30; // between OEM and new holder
	MountOffset = 20.0;

	/* [Hidden] */

	HoleWindage = 0.2;
	Protrusion = 0.1;
	NumSides = 334;

	ID = 0;
	OD = 1;
	LENGTH = 2;

	Insert = [21.0,24.5,35.0]; // hose connector taper
	PlugSize = Insert + [-0.3,-0.3,0]; // … for better fit in OEM holder

	Slot = [Insert[OD],14.6,3*Insert[LENGTH]]; // slot on OEM holder, arbitrary length

	WallThick = 8.0; // holder wall thickness
	Radius = 3.0; // shapely rounding

	$fn=NumSides;

	//———-
	// Define Shapes

	module Plug() {

	cyl(l=Insert[LENGTH],d1=PlugSize[ID],d2=PlugSize[OD],anchor=BOTTOM);

	}

	module Socket() {

	difference() {
	tube(l=Insert[LENGTH],id1=Insert[ID],id2=Insert[OD],wall=WallThick,anchor=BOTTOM);
	cuboid(Slot + [0,1.0,0],anchor=LEFT+CENTER);
	right(Insert[OD]/2)
	cube([Insert[OD],Insert[OD] + 2WallThick,3Insert[LENGTH]],anchor=LEFT+CENTER);
	}

	}

	module Connector() {

	difference() {
	left(MountOffset)
	cuboid([MountOffset + Insert[LENGTH]sin(MountAngle),Slot.y,Insert[LENGTH]cos(MountAngle)],
	anchor=LEFT+BOTTOM);
	yrot(MountAngle) right(Insert[ID]/2 + WallThick)
	cyl(l=Insert[LENGTH],d1=Insert[ID] + 2WallThick,d2=Insert[OD] + 2WallThick,anchor=BOTTOM);

	}

	}

	module Adapter() {

	union() {
	left(MountOffset)
	Plug();
	yrot(MountAngle) right((Insert[ID] + 2*WallThick)/2)
	Socket();
	Connector();
	}
	}

	//———-
	// Build things

	if (Layout == "Plug")
	Plug();

	if (Layout == "Socket")
	Socket();

	if (Layout == "Connector")
	Connector();

	if (Layout == "Show")
	Adapter();

	if (Layout == "Build")
	up(Insert[ID]/2 + 1*WallThick + Insert[OD]/2)
	yrot(90-MountAngle)
	Adapter();

view raw Delta shower head holder extension.scad hosted with ❤ by GitHub

2025-05-05

Metal Spring Clamp: TPU Jaw Pads

Setting up the Makergear M2 to print TPU (eSun 95A) involved a cold pull to get the remaining PETG out of the nozzle, some manual flushing, then printing test cubes to figure out a reasonable speed / temperature combination:

Makergear M2 - first TPU test cube — Makergear M2 – first TPU test cube

A 10 mm solid cube came out overstuffed and the first 20 mm cube lacked enough infill to hold its top up, but the third cube looked surprisingly good at 230 °C and 30 mm/s with 15% 3D Honeycomb infill:

Makergear M2 - TPU test cubes — Makergear M2 – TPU test cubes

With that settled, I conjured pairs of soft (-ish) jaw pads for the far-too-many metal spring clamps having worn out their vinyl pads:

Spring clamp jaws - installed — Spring clamp jaws – installed

Those were the first attempt and worked well enough to suggest nicely rounded endcaps instead of flat cylinders:

Spring Clamp Jaws - show view — Spring Clamp Jaws – show view

Unlike the first version, they now build standing on their rectangular clamp jaw opening:

Spring Clamp Jaws - slicer preview — Spring Clamp Jaws – show view

Those two groups have different lengths (1 inch and 1-⅛ inch) with PrusaSlicer combining the OpenSCAD program’s output.

The as-built pads are essentially un-photographable:

Spring clamp jaws - group build — Spring clamp jaws – group build

TPU is tough enough to make the single-layer brim un-tearable, but they’re easy enough to separate & trim with scissors. Even the 5 mm brim has a tenuous grip on glass + Suave hair “spray” applied from a dropper bottle, so I should try a BuildTak sheet that’s been on the to-do pile for far too many years.

Similarly, TPU is flexy enough to make a precise fit unnecessary: push firmly to force the pads onto the jaws and you’re done.

The OpenSCAD source code as a GitHub Gist:

	// Spring clamp replacement jaw pad
	// Ed Nisley – KE4ZNU
	// 2025-04-26

	include <BOSL2/std.scad>

	Layout = "Show"; // [Show,Build,Clamp]

	Ends = "Round"; // [Flat,Round]

	Sets = 1;

	/* [Hidden] */

	HoleWindage = 0.2;
	Protrusion = 0.1;
	NumSides = 234;

	WallThick = 2.0;

	CushionOD = 10.0;
	CushionStem = 10.0;

	JawAngle = 60/2; // just for Show

	JawWidth = 1.000*INCH; // clamps are hard-inch sizes: 1.0 and 1.125

	Jaw = [1.5,50,JawWidth]; // roughly one jaw

	Gap = 2.0;

	$fn = 234;

	//———-
	// Define objects

	//—–
	// Clamp jaw

	module Clamp() {

	up(WallThick)
	cuboid(Jaw,anchor=BOTTOM+BACK);

	}

	module Pad() {

	difference() {
	union() {
	cyl(d=CushionOD,h=Jaw.z + 2*WallThick,anchor=BOTTOM,
	rounding = (Ends == "Flat") ? 0 : CushionOD/2);
	cuboid([Jaw.x + 2WallThick,CushionStem,Jaw.z + 2WallThick],
	rounding=WallThick/2,anchor=BOTTOM+BACK);
	}
	Clamp();
	}
	}

	//———-
	// Build things

	if (Layout == "Clamp") {
	Clamp();
	}

	if (Layout == "Show") {
	for (i = [-1,1])
	right(i*(CushionOD + Gap)/2)
	zrot(i*JawAngle) {
	Pad();
	color("Silver",0.5)
	Clamp();
	}
	}

	if (Layout == "Build") {
	for (n = [0:(Sets – 1)])
	for (i = [-1,1])
	right(i((CushionOD + Gap)/2 + n(CushionOD + Gap)))
	up(CushionStem) back(Jaw.z/2) xrot(90)
	Pad();
	}

view raw Spring Clamp Jaw Pads.scad hosted with ❤ by GitHub

2025-04-30

Improved Sony AS30V Helmet Mount Adapter Plate

Last week a wind gust blew my Tour Easy over while resting on its kickstand at Mary’s garden; I rarely depend on the kickstand for that very reason, but some days are like that. Anyhow, the mount for the Sony AS30V helmet camera did exactly what it should by releasing the camera, rather than grinding it into the ground.

Calling it a “mount” may be overstating the case:

Sony HDR-AS30V camera on bike helmet - inverted — Sony HDR-AS30V camera on bike helmet – inverted

I was still using that helmet, albeit with a better mirror mount, but it was getting rather crusty and the hook-n-loop straps were definitely sun-faded, so I built a better mount with an adapter plate matching a new-old-stock helmet from the stash:

Sony AS30V Helmet mount - side view — Sony AS30V Helmet mount – side view

The white slab atop the helmet curves to match the helmet contour, with the ridge fitting into the vent slot:

AS30 helmet mount - solid model - show view — AS30 helmet mount – solid model – show view

OK, the helmet isn’t orange, but you get the idea. The sphere has a 153 mm radius, calculated from the Official Sony helmet mount’s bottom curve, minus a ring shaping the central groove:

AS30 helmet mount - solid model - tab ring — AS30 helmet mount – solid model – tab ring

This upside-down view shows the interesting parts:

AS30 helmet mount - solid model — AS30 helmet mount – solid model

The flat side sticks to the camera’s holder with a custom-cut sheet of craft adhesive shaped like this:

AS30 helmet mount - glue — AS30 helmet mount – glue

The overall outline of those things comes from a scan of the bottom of the Sony camera holder, passed through Inkscape and LightBurn to generate the curves:

The large notches in the sides pass hook-n-loop straps intended to break away when the helmet hits the ground again. The front tunnel (of two, because symmetry) passes a cable tie preventing the camera from parting company with the mount during normal riding and holding the yellow latch in the Locked position:

Sony AS30V Helmet mount - rear view — Sony AS30V Helmet mount – rear view

It is just barely possible to slide the cable tie over the front of the camera to release the latch.

The camera rides upside-down to protect the lens from scuffs and scrapes. Fortunately, there’s a setting to invert the picture.

For completeness, the front view:

Sony AS30V Helmet mount - front view — Sony AS30V Helmet mount – front view

The furry patch covers the microphone pores to kill (most of) the wind noise.

The sharp ventral angle matches the helmet’s midline ridge in the back, but obviously isn’t needed over the vent hole in the front. I decided to not bother making a comprehensive model of the hole, not least because I didn’t really know the camera’s exact front-to-back location.

Works fine where it sits, though:

Burnett Signal Timing - 2025-04-23 — Burnett Signal Timing – 2025-04-23

NYSDOT’s signal timing at Burnett Blvd and Rt 55 remains bicycle-hostile, same as it ever was.

The OpenSCAD source code and baseplate shape as a GitHub Gist:

	// Sony AS30 helmet mount
	// Ed Nisley – KE4ZNU
	// 2025-04-20

	include <BOSL2/std.scad>

	Layout = "Show"; // [Show,Build,Ball,Tab,Glue]

	Gap = 5; // [0:5:20]

	/* [Hidden] */

	HoleWindage = 0.2;
	Protrusion = 0.1;

	WallThick = 1.0; // enough stiffness against flat pad

	HelmetRadius = 153.0; // from chord equation on curved pad = magic number
	Groove = [30.0,100,3.0,]; // roughly the groove along helmet midline

	Pad = [38,53,10]; // baseplate size, thick enough without fancy trig

	Strap = [3.0,15.0,10*Pad.z]; // hook-n-loop strap holes, double-thick

	Tie = [100,6.0,2.0 + Protrusion]; // cable tie around camera
	TieOffset = 14.0; // … from end of pad

	$fn=96;

	//———-
	// Define shapes

	module Ball() {

	difference() {
	sphere(r=HelmetRadius);
	Tab();
	}

	}

	// Rough approximation of the helmet groove

	module Tab() {

	m = 2.0; // roughly the chord height beyond the tab

	rotate_extrude(convexity=10) {
	right(HelmetRadius)
	zrot(180)
	polygon([
	[0,0],
	[0,Groove.x/2],[Groove.z + m,Groove.x/2],[m,0],
	[Groove.z + m,-Groove.x/2],[0,-Groove.x/2],
	[0,0]
	],convexity=10);
	}

	}

	// Baseplate with all the cutouts

	module BasePlate() {

	difference() {
	linear_extrude(height=Pad.z,convexity=10)
	import("AS30 Baseplate layout.svg",layer="Baseplate");
	up(WallThick + HelmetRadius)
	yrot(90)
	Ball();
	for (i = [-1,1]) // strap clearance at edge of helmet hole
	right(i*Groove.x/2)
	cube([(Pad.x – Groove.x)/2,Strap.y,Strap.z],center=true);
	for (i = [-1,1]) // cut through edge of pad
	right(i*Pad.x/2)
	cube([(Pad.x – Groove.x),Strap.y,Strap.z],center=true);
	for (j = [-1,1])
	fwd(j*(Pad.y/2 – TieOffset)) up(WallThick)
	cuboid(Tie,anchor=BOTTOM);
	}
	}

	//———-
	// Build things

	if (Layout == "Glue")
	projection(cut=true)
	BasePlate();

	if (Layout == "Tab")
	Tab();

	if (Layout == "Show") {
	xrot(180)
	BasePlate();
	down(WallThick + HelmetRadius + Gap)
	yrot(90)
	color("Orange",0.75) Ball();
	}

	if (Layout == "Build")
	BasePlate();

	if (Layout == "Ball")
	Ball();

view raw AS30 helmet mount.scad hosted with ❤ by GitHub

	<?xml version="1.0" encoding="UTF-8" standalone="no"?>
	<!– Created with Inkscape (http://www.inkscape.org/) –>

	<svg
	width="11in"
	height="8.5in"
	viewBox="0 0 279.40056 215.90043"
	version="1.1"
	id="SVGRoot"
	inkscape:version="1.4.1 (93de688d07, 2025-03-30)"
	sodipodi:docname="AS30 Baseplate layout.svg"
	xml:space="preserve"
	xmlns:inkscape="http://www.inkscape.org/namespaces/inkscape"
	xmlns:sodipodi="http://sodipodi.sourceforge.net/DTD/sodipodi-0.dtd"
	xmlns:xlink="http://www.w3.org/1999/xlink"
	xmlns="http://www.w3.org/2000/svg"
	xmlns:svg="http://www.w3.org/2000/svg"
	xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
	xmlns:cc="http://creativecommons.org/ns#"><sodipodi:namedview
	id="namedview7"
	pagecolor="#ffffff"
	bordercolor="#0000ff"
	borderopacity="1"
	inkscape:pageshadow="0"
	inkscape:pageopacity="0"
	inkscape:pagecheckerboard="1"
	inkscape:document-units="mm"
	showgrid="true"
	units="mm"
	gridtolerance="9.9"
	guidetolerance="10.4"
	inkscape:snap-perpendicular="true"
	inkscape:snap-tangential="true"
	width="700mm"
	borderlayer="false"
	inkscape:showpageshadow="true"
	viewbox-width="700"
	guidecolor="#ff00e3"
	guideopacity="0.49803922"
	inkscape:zoom="1.6945884"
	inkscape:cx="86.451671"
	inkscape:cy="111.82656"
	inkscape:window-width="1780"
	inkscape:window-height="1091"
	inkscape:window-x="0"
	inkscape:window-y="0"
	inkscape:window-maximized="0"
	inkscape:current-layer="layer1"
	objecttolerance="31"
	inkscape:deskcolor="#d1d1d1"
	showguides="true"><inkscape:grid
	type="xygrid"
	id="grid9"
	units="mm"
	spacingx="5"
	spacingy="5"
	dotted="false"
	empspacing="2"
	originx="148.5"
	originy="127.29919"
	color="#ff0000"
	opacity="0.18431373"
	empcolor="#4040ff"
	empopacity="0.49411765"
	visible="true" /><sodipodi:guide
	position="157.7549,120.64599"
	orientation="1,0"
	id="guide1"
	inkscape:locked="false" /></sodipodi:namedview><defs
	id="defs2" /><g
	inkscape:label="Baseplate"
	inkscape:groupmode="layer"
	id="layer1"
	transform="translate(0,5.4354331)"><path
	id="path1"
	style="fill:none;fill-rule:evenodd;stroke:#0c96d9;stroke-width:0.0998686;stroke-linejoin:round"
	d="m -18.99969,190.42075 3.09576,-6.45581 h 32.08112 l 2.82285,6.45581 -10e-6,40.00473 -3.02778,6.53957 -31.33905,-0.14658 -3.63324,-6.39299 z"
	sodipodi:nodetypes="ccccccccc"
	inkscape:label="Aligned path" /></g><g
	inkscape:groupmode="layer"
	id="layer2"
	inkscape:label="Original"><image
	width="57.658115"
	height="65.193459"
	preserveAspectRatio="none"
	xlink:href="AS30%20Baseplate%20scan.jpg"
	id="image1"
	x="112.42073"
	y="67.772316"
	transform="rotate(0.87516737,-355.84202,2.7177945)"
	style="display:inline" /><path
	id="rect1"
	style="fill:none;fill-rule:evenodd;stroke:#0c96d9;stroke-width:0.0998686;stroke-linejoin:round"
	d="m 120.39572,83.160307 3.09576,-6.45581 h 32.08112 l 2.82285,6.45581 -1e-5,40.004733 -3.02778,6.53957 -31.33905,-0.14658 -3.63324,-6.39299 z"
	sodipodi:nodetypes="ccccccccc"
	transform="translate(0,5.4354331)" /></g><metadata
	id="metadata11"><rdf:RDF><cc:Work
	rdf:about=""><cc:license
	rdf:resource="http://creativecommons.org/licenses/by-nc-sa/4.0/" /></cc:Work><cc:License
	rdf:about="http://creativecommons.org/licenses/by-nc-sa/4.0/"><cc:permits
	rdf:resource="http://creativecommons.org/ns#Reproduction" /><cc:permits
	rdf:resource="http://creativecommons.org/ns#Distribution" /><cc:requires
	rdf:resource="http://creativecommons.org/ns#Notice" /><cc:requires
	rdf:resource="http://creativecommons.org/ns#Attribution" /><cc:prohibits
	rdf:resource="http://creativecommons.org/ns#CommercialUse" /><cc:permits
	rdf:resource="http://creativecommons.org/ns#DerivativeWorks" /><cc:requires
	rdf:resource="http://creativecommons.org/ns#ShareAlike" /></cc:License></rdf:RDF></metadata></svg>

view raw gistfile1.txt hosted with ❤ by GitHub

2025-04-25

HQ Sixteen: Handlebar Control Button Labels

The recessed faceplate on the new handlebar control caps for Mary’s HQ Sixteen puts the label flush with the rim:

Control Button Caps - solid model - show view assembled — Control Button Caps – solid model – show view assembled

The current version of the labels isn’t much to look at:

HQ Sixteen control caps - new caps — HQ Sixteen control caps – new caps

The OpenSCAD code produces an SVG outline of the faceplate, surrounded by four alignment targets:

Control Button Caps - solid model - face view — Control Button Caps – face view

Import the SVG into Inkscape and tart it up:

Control Button Caps - Inkscape — Control Button Caps – Inkscape

The alert reader will note the labels are swapped left-for-right.

The black characters on the left get printed on heavy white paper and laminated; feel free to add artistic embellishments. You must delete the cyan-ish shapes showing the faceplate and switch openings, which just show where the characters will end up, but you must print the four corner targets for alignment.

The red and orange shapes on the right define the outlines for laser-cutting the laminated paper and adhesive sheet after you import the Inkscape SVG file into LightBurn. The Inkscape colors will automagically put the shapes on separate LightBurn layers, with the cyan-ish shapes going onto non-cutting Tool Layer T2.

Set the cutting speed & feed to match your machine, lay the laminated labels on the platform, use Print and Cut to align two diagonal corner targets with the corresponding printed targets, then Fire. The. Laser.

The orange shapes have half a millimeter inset to leave a slight non-sticky margin around the edges:

HQ Sixteen control caps - adhesive layer — HQ Sixteen control caps – adhesive layer

Although those shapes have the same four targets, you align the adhesive by hand and eye. Cut them out, peel one side, stick adhesive to the label, peel the other side, stick adhesive to the faceplate, and you’re done.

Now, to figure out the switch wiring …

2025-04-21

Category: Software

3D Printed 20×102mm Cartridge

Polymaker PolyDryer Box: PC4 Fitting Adapter

Anker LC-40 Flashlight Switch Repair

Delta Shower Head Holder Extension

Metal Spring Clamp: TPU Jaw Pads

Improved Sony AS30V Helmet Mount Adapter Plate

HQ Sixteen: Handlebar Control Button Labels