The New Hotness

At some point along the way, the bright yellow washer (they call it a “spacer”) on Mary’s 60 mm Olfa rotary cutter went missing. A casual search suggests that replacement washers come directly from Olfa after navigating their phone tree, but …

Judging from scuffs on the rear surface, the washer serves two purposes:

Hold the blade close to the handle against slightly misaligned cutting forces
Add more compression to the wave washer under the nut

This model is much more intricate than the stock washer:

Olfa Rotary Cutter - backing washer — Olfa Rotary Cutter – backing washer

The trench across the middle of the thicker part allows a wider compression adjustment range for the wave washer and provides more thread engagement at the lightest setting for my liking. The shape comes from the chord equation based on measurements of the wave washer:

Olfa Rotary Cutter - washer doodles — Olfa Rotary Cutter – washer doodles

The wave washer keys on the bolt flats: the whole affair rotates with the blade and gives the nut no inclination to unscrew. If you remove the trench, the remaining hole has the proper shape to key on the bolt and rotate with it; with the trench in place, the wave washer’s sides haul the plastic washer along with it.

The plain ring, just two threads thick, glues bottom-to-bottom on the thicker part to soak up the air gap and provide more blade stability. It’s not entirely clear that’s a win; it’s easy to omit.

It looks about like you’d expect:

Olfa Rotary Cutter - washer in place — Olfa Rotary Cutter – washer in place

The wave washer must go on the bolt with the smooth curve downward into the trench. That orientation that wasn’t enforced by the Official Olfa spacer washer’s smooth sides.

The nut sits upside-down to show the face that normally sits against the wave washer. I’d lay long odds that the recess around the threads originally held a conical compression spring with a penchant for joining the dust bunnies under the sewing table. You can insert the wave washer the wrong way, but it doesn’t store enough energy to go airborne unless you drop it, which did happen once with the expected result.

The OpenSCAD source code as a GitHub gist:

	// Olfa rotary cutter backing washer
	// Ed Nisley KE4ZNU January 2016

	Layout = "Build";

	//- Extrusion parameters must match reality!
	// Print with +1 shells and 3 solid layers

	ThreadThick = 0.20;
	ThreadWidth = 0.40;

	HoleWindage = 0.2;

	function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

	Protrusion = 0.1; // make holes end cleanly

	//———————-
	// Dimensions

	WasherOD = 35.0;
	WasherThick = 1.5;

	WaveOD = 14.0; // wave washer flat dia
	WaveM = 1.8; // height of wave washer bend
	BendRad = (pow(WaveM,2) + pow(WaveOD,2)/4) / (2*WaveM); // radius of wave washer bend

	echo(str("Wave washer bend radius: ",BendRad));

	SpacerID = WaveOD + 2.0;
	SpacerThick = 2*ThreadThick;

	NumSides = 12*4;
	$fn = NumSides;
	//———————-
	// Useful routines

	module PolyCyl(Dia,Height,ForceSides=0) { // based on nophead's polyholes

	Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);

	FixDia = Dia / cos(180/Sides);

	cylinder(r=(FixDia + HoleWindage)/2,
	h=Height,
	$fn=Sides);
	}

	//———————-
	// Parts

	module Upper() {
	difference() {
	cylinder(d1=WasherOD,d2=(WasherOD – 2.0),h=WasherThick);
	translate([0,0,-Protrusion])
	intersection() {
	PolyCyl(8.2,2.0,8);
	cube([(6.0 + HoleWindage),10,2*WasherThick],center=true);
	}
	translate([-(WaveOD + 1.0)/2,0,BendRad])
	rotate([0,90,0]) rotate(0*180/16)
	PolyCyl(BendRad*2,(WaveOD + 1),16);
	}
	}

	module Spacer() {
	difference() {
	cylinder(d=WasherOD,h=SpacerThick);
	translate([0,0,-Protrusion])
	cylinder(d=SpacerID,h=2*SpacerThick);
	}
	}

	//———————-
	// Build it!

	if (Layout == "Show") {
	translate([0,0,SpacerThick])
	color("Cyan")
	Upper();
	color("LightCyan")
	Spacer();
	}

	if (Layout == "Build") {
	translate([-0.6*WasherOD,0,0])
	Upper();
	translate([0.6*WasherOD,0,0])
	Spacer();
	}

view raw Olfa Rotary Cutter.scad hosted with ❤ by GitHub

The New Hotness

Olfa Rotary Cutter Spacer