Spring cleaning provided the opportunity for Yet Another Episode in my long-standing battle with the Whirlpool refrigerator entropy generator:

That little thing supports half the weight of the two drawers across the bottom of the refrigerator; how such a thin plastic member was supposed to be adequate to the task continues to escape me.

If we had to pay real money for all the repairs I’ve made to that piece of crap, we’d have replaced it long ago. The only thing that hasn’t failed so far is the compressor, so driving it until it drops continues to make sense; replacing a working anything seems like a bad idea.

Thirteen years after the original repair on the left side and eight years after I fixed the drawer slide on the right side, this happened:

Refrigerator shelf slide – failed parts

The general idea is to wrap a new bracket around the old bracket, because trying to remove the old one will probably cause more damage:

Refrigerator shelf slide – trial assembly

A pair of screws hold the new bracket to the shelf support:

Refrigerator shelf slide – support screw nut openings

Those two screws must support the entire weight of the drawer, which is exactly what broke the original all-plastic frame and slide.

The epoxy chip and transparent plastic sheet in the first picture spaced the old aluminum bracket away from the shelf support and reduced the space beyond the new bracket enough to require drilling access holes. Fortunately, they’re hidden inside the support frame, so nobody will ever know.

The shelf support is a huge floppy rectangle, so I clamped it to the bench vise while drilling the holes:

Refrigerator shelf slide – upright vise clamp

The new bracket is on the right, with a sheet of white acrylic spacing it away from the shelf support by exactly the same distance as the angled aluminum snippet replacing the failed epoxy & plastic on the broken part:

Refrigerator shelf slide – bracket parts

The two holes in the middle of the aluminum parts show that I used exactly the same angle brackets as raw material. It’ll be a sad day when I eventually use the last of those brackets.

Putting the parts together, with double-stick tape holding all the parts in place, shows how they fit:

Refrigerator shelf slide – repair trial assembly

And then it just snapped into place. I didn’t bother pretending solvent glue would help anything, nor did I apply any epoxy, so this whole thing hangs from those two 4-40 screws. On the other paw, their steel beats the original white plastic.

I devoutly hope to never rebuild the actual drawer slide, but these dimensions may help somebody else out of a jam:

Refrigerator shelf slide – dimensions

The vertical “40” dimension refers to the available space from the bottom of the white plastic part to the top of the shelf support frame; the new bracket is a tad shorter than that.

The plastic parts in that refrigerator have been a complete disappointment: were it not for my relentless repair jones, we’d likely be on our third or fourth refrigerator by now. Oddly, the cooling parts continue to chug along (*), without more than the occasional loud noise in the middle of the night.

We’re definitely doing our part to reduce our waste stream.

(*) The most recent freezer fan hasn’t failed yet!

The support holding the two big drawers below the bottom shelf of our long-suffering Whirlpool refrigerator broke off. Having previously repaired and then replaced the tab holding the strut in place, then added metal skid plates to the bearing surfaces, I’m getting pretty good at fighting this particular bit of entropy to a standstill:

Refrigerator strut – clamped glue joint

Adding a few more clamps always make me feel good:

Refrigerator strut – many clamps

Although a good solvent-bond joint should be as strong as the original plastic, that’s not saying much: I expect the end of that strut will break off again. Perhaps the central web is wide enough for a few small screws?

The tab supporting the strut with the center slides for the lower drawers in our Whirlpool refrigerator broke of its own accord. This is a problem of long standing, somewhat exacerbated by the fact that lifting the strut will break the tab without much effort at all, but this time the drawers pulled the strut downward hard enough to not only break the tab, but also tear the small tabs that align the bracket right out of the frame.

While pondering the problem, I glued the broken chunk back into the frame:

Refrigerator Drawer Strut – clamping front plate

We agreed that, after nigh onto two decades, it would be OK to swap the position of the two drawers, so as to let the strut use the undamaged part of the frame seen below. Presumably, we’ll eventually get used to having the apples on the right and the veggies on the left.

But it was obvious Something Serious Had To Be Done about the tab.

The tab should align like this inside the frame:

Refrigerator Drawer Strut Tab – alignment

The rightmost part of the tab rests atop a U-shaped metal bar that also supports and stiffens the entire front of the frame, but cantilevering the weight of both drawers on that extended tab overpowered my last attempt at making a glue joint. Soooo, I decided to build a (wait for it …) 3D printed part that screws firmly to the front of the strut.

The first step involved introducing the strut to Mr Belt Sander to strip the wreckage of the OEM tab from the front end (visible through the opening) and smooth things out, then measuring the remainder. The locating flange inside the frame almost defeated me, but eventually I found a tool that fit inside the strut opening and around the flange:

Refrigerator Drawer – measuring flange

Which produced a sketch of the key dimensions:

Refrigerator Drawer Strut – Dimension Doodles

Which became an extruded polygon with a few holes punched in the side:

Refrigerator Shelf Strut Tab – solid model

Building it standing up wraps the plastic threads around the entire tab and stacks the layers along the length of the tab. Doing it lying down in the obvious hump-up orientation would put the layers parallel to the bottom surface, where they can pull apart under load.

The key innovation here involves being willing to assemble the tab to the strut in situ, without insisting it fit through the frame opening and be more-or-less easily removable. That let me bulk up the tab to match the end of the strut, fill the entire frame opening with plastic, and get enough bulk for a pair of 4-40 screws that, being loaded in shear, should withstand the weight of all those fruits & veggies in the drawers.

The screws simply thread into the holes in the tab, without benefit of tapping. The OpenSCAD code now includes a pair of nut traps, but I’m hoping they won’t be needed.

The new tab really does fill the space available:

Refrigerator Drawer Strut – new tab in place

The OpenSCAD code now moves the notch half a millimeter further away from the strut to center it over the ridge. What’s not obvious is how the frame slants toward the tab over the U-bar: the tab just barely clears and probably should have a tapered nose. You may add that if you like.

The U-shaped bar constrains the tab pretty firmly and supports the end, which should now be plump enough to withstand the forces involved. The screws sit horizontally with the frame installed and can’t pull out, which is why I think they can get along without nut traps.

It’s built in cyan PETG with three perimeter threads and 40% 3D Honeycomb fill, making it essentially a solid block of plastic; it’ll be interesting to see what fails next.

The OpenSCAD source code, which I hammered out in a white-hot fury:

// Refrigerator Shelf Strut Tab
// Ed Nisley KE4ZNU December 2015

//- Extrusion parameters must match reality!

ThreadThick = 0.25;
ThreadWidth = 0.40;

HoleWindage = 0.2;

Protrusion = 0.1;			// make holes end cleanly

inch = 25.4;

function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

//----------------------
// Dimensions

TabSize = [20.0,12.0,35.0];							// length from bracket, height, width along front

SlotSize = [3.0,7.0];
SlotX = 7.0;

TabProfile = [
	[0,0],
	[12,0],	[12,7.0],
	[TabSize[0],7.0], [TabSize[0],TabSize[1]],
	[SlotX + SlotSize[0]/2,TabSize[1]],
	[SlotX + SlotSize[0]/2,5.0], [SlotX - SlotSize[0]/2,5.0],
	[SlotX - SlotSize[0]/2,TabSize[1]],
	[0,TabSize[1]]
];

ScrewY = 7.0;
ScrewOC = 25.0;
ScrewOD = 2.5;

NutOD = 6.6;					// across flats
NutThick = 2.5;

//----------------------
// Useful routines

module PolyCyl(Dia,Height,ForceSides=0) {			// based on nophead's polyholes

  Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);

  FixDia = Dia / cos(180/Sides);

  cylinder(r=(FixDia + HoleWindage)/2,
		h=Height,
	$fn=Sides);
}

//----------------------
// Build it

difference() {
	linear_extrude(height=TabSize[2],convexity=4)
		polygon(points=TabProfile);
	
	for (i=[-1,1]) {
		translate([-Protrusion,ScrewY,i*ScrewOC/2 + TabSize[2]/2])
			rotate([0,90,0])
				rotate(180/6)
					PolyCyl(ScrewOD,SlotX,6);
		translate([SlotX - SlotSize[0]/2 - NutThick - Protrusion,ScrewY,i*ScrewOC/2 + TabSize[2]/2])
			rotate([0,90,0])
				rotate(180/6)
					PolyCyl(NutOD,NutThick + SlotSize[0],6);
	}
}

Maybe that’ll last until we finally scrap out the refrigerator…

Well, another year, another deep-cleaning session, another break in the strut holding up the drawers in the Whirlpool refrigerator:

Whirlpool refrigerator drawer strut – clamped

This time, there’s a fixture positioning the tab in the proper orientation while the solvent evaporates. The two bottom clamps hold an aluminum plate against the top (far side) of the strut, with the top-center clamp holding the tab against a steel block shimmed with cardboard to get the correct angle. The other two clamps squash the tab against the joint, which is well-soaked with IPS 4 adhesive.

I replaced the right-side guide plate, originally made from phosphor bronze strip, with some thicker steel strip. The bronze strip collapsed into the worn section of the plastic bump that appeared in the previous post:

Refrigerator strut – worn retainers

I’ve written bigger caution messages on the top of the strut in red letters, but we think it’s getting on time for a whole new refrigerator…

The strut supporting the two drawers in the bottom of the refrigerator came out in two pieces during a recent cleaning session. To judge from the condition of the joint, I’d done this once before in its history:

Refrigerator strut – tab clamps

That tab inserts into a slot in the front of the elaborate frame that supports the drawers, where it’s captured by a metal bar. Should you lift the rear of the strut without first removing the bar, the tab snaps off at the base. I’ve annotated the top of the strut in the hopes of reminding me the next time around.

A pair of bumps at the front of the drawer guides should hold the drawers closed, but it’s pretty obvious that’s not working as intended:

Refrigerator strut – worn retainers

I shaped strips of phosphor bronze spring stock around the bumps:

Refrigerator strut – phosphor bronze covers – top

The bottom view shows they’re held in place by crimps and a generous dollop of faith:

Refrigerator strut – phosphor bronze covers – bottom

That should serve until I know whether the plastic drawer rail will carve through the metal. The drawers slide out with much more enthusiasm now, so it’s a Good Thing until something else breaks.

Yes, this is the refrigerator with the Freezer Dog…

Somehow, one of the brackets that supports the small shelf inside the freezer of our Whirlpool refrigerator went missing over the many intervening years and repairs; we never used that shelf and stashed it in a closet almost immediately after getting the refrigerator, so not having the bracket didn’t matter. We recently set up a chest freezer in the basement for all the garden veggies that used to fill all the space available and decided to (re-)install the shelf, which meant we needed a bracket.

It’s impossible to figure out exactly which “shelf stud” in that list would solve the problem, but one of the upper-left pair in that set seems to be about right. On the other paw, I don’t need all the other brackets and doodads and screws, sooo… I can probably make one.

Start with a few measurements, then doodle up the general idea:

Refrigerator Bracket – dimension doodlet’s time to conjure up a solid model:

A bit of OpenSCAD solid modeling:

Refrigerator Bracket Pin – solid model

The yellow bars support the ceiling of that big dovetail, which would otherwise sag badly. The OEM bracket has nicely rounded corners on the base and a bit of an overall radius at the end of the post; this was pretty close and easier to do.

Now it’s time to Fire the Thing-O-Matic…

I switched from blue to white filament during the print, because I figured I’d print another one after I got the sizes right, so it emerged with an attractive blue base:

Bracket on build platform

A better view of the support structure:

Bracket – dovetail support structure

Two of the bars snapped off cleanly, but the third required a bit of scraping:

Bracket – support scars

Somewhat to my surprise, Prototype 001 slipped snugly over the matching dovetail on the freezer wall, with about the same firm fit as the OEM brackets:

Refrigerator bracket – installed

And it works perfectly, apart from that attractive blue base that I suppose we’ll get used to after a while:

Refrigerator bracket – in use

I have no idea whether ABS is freezer-rated. It seems strong enough and hasn’t broken yet, so we’ll declare victory and keep the source code on tap.

The whole project represents about an hour of hammering out OpenSCAD code for the solid model and another hour of printing, which means I’d be better off to just buy the parts kit and throw away the unused bits. Right?

I loves me my Thing-O-Matic…

The OpenSCAD source code:

// Shelf support bracket
// for Whirlpool freezer
// Ed Nisley KE4ZNU Octoboer 2012

//include </mnt/bulkdata/Project Files/Thing-O-Matic/MCAD/units.scad>
//include </mnt/bulkdata/Project Files/Thing-O-Matic/Useful Sizes.scad>

// Layout options

Layout = "Build";
 // Overall layout: Show Build
 // Printing plates: Build
 // Parts: Post Base Keystone Support

ShowGap = 10; // spacing between parts in Show layout

//- Extrusion parameters must match reality!
// Print with +1 shells and 3 solid layers

ThreadThick = 0.25;
ThreadWidth = 2.0 * ThreadThick;

HoleWindage = 0.2;

function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

Protrusion = 0.1; // make holes end cleanly

//----------------------
// Dimensions

PostLength = 17.5;
PostWidth = 8.2;
PostHeight = 14.4;
PostOffset = 4.4;

PostTopWidth = 4.0;
PostTopHeight = 4.2;

BaseLength = 22.6;
BaseWidth = 20.8;
BaseThick = 5.0;

KeystoneOffset = 3.4;
KeyThick = IntegerMultiple(3.0,ThreadThick);
KeyBase = 2.5;
SlotOpening = 11.63;
//----------------------
// Useful routines

module PolyCyl(Dia,Height,ForceSides=0) { // based on nophead's polyholes

Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);

FixDia = Dia / cos(180/Sides);

cylinder(r=(FixDia + HoleWindage)/2,
 h=Height,
 $fn=Sides);
}

module ShowPegGrid(Space = 10.0,Size = 1.0) {

 Range = floor(50 / Space);

 for (x=[-Range:Range])
 for (y=[-Range:Range])
 translate([x*Space,y*Space,Size/2])
 %cube(Size,center=true);

}

//-------------------
// Component parts

//--- Post

module Post(h=PostLength) {

PostTopAngle = atan((PostWidth - PostTopWidth)/(2*PostTopHeight));
PostBottomRadius = PostWidth/2;

PostPolyTop = [PostTopWidth/2,0];
PostPolyBottom = [PostWidth/2,-PostTopHeight];

hull() {
 linear_extrude(height=h) {
 polygon(points=[
 [-PostPolyTop[0],PostPolyTop[1]],
 PostPolyTop,
 PostPolyBottom,
 [-PostPolyBottom[0],PostPolyBottom[1]]
 ]);
 translate([0,-PostHeight + PostBottomRadius])
 circle(r=PostBottomRadius,$fn=4*8);
 }
 }
}

//--- Base block

module Base() {

 linear_extrude(height=BaseThick)
 square([BaseWidth,BaseLength],center=true);

}

//-- Keystone slot

module Keystone() {

Tx = SlotOpening/2 + KeyBase;

 rotate([90,0,0])
 linear_extrude(height=BaseLength)
 polygon(points=[
 [-Tx,KeyThick],
 [ Tx,KeyThick],
 [ SlotOpening/2,0],
 [ SlotOpening/2,-Protrusion],
 [-SlotOpening/2,-Protrusion],
 [-SlotOpening/2,0]
 ]);
}

//--- Support structure

module Support() {

SupportLength = BaseLength - 2*ThreadWidth;
SupportWidth = 2*ThreadWidth;
SupportHeight = KeyThick - Protrusion;

SupportPeriod = 7.0*ThreadWidth;

SupportBeams = 3; // must be odd -- choose to fit
SIndex = floor((SupportBeams - 1)/2);

for (i=[-SIndex:SIndex])
 translate([(i*SupportPeriod - SupportWidth/2),-(SupportLength + ThreadWidth),0])
 color("Yellow") cube([SupportWidth,SupportLength,SupportHeight]);
}

//--- The whole thing!

module Bracket(ShowSupp) {

 union() {
 difference() {
 Base();
 translate([0,(BaseLength/2 - KeystoneOffset),0])
 Keystone();
 }
 translate([0,(BaseLength/2 - PostOffset),BaseThick - Protrusion])
 Post(h=(PostLength + Protrusion));
 }

 if (ShowSupp)
 translate([0,(BaseLength/2 - KeystoneOffset),0])
 Support();

}

//----------------------
// Build it!

ShowPegGrid();

if (Layout == "Show")
 Bracket(false);

if (Layout == "Build")
 Bracket(true);

if (Layout == "Post")
 Post();

if (Layout == "Base")
 Base();

if (Layout == "Keystone")
 Keystone();

if (Layout == "Support") {
 Support();
% Keystone();
}