Strange though it may seem, the kitchen faucet handle broke while Mary was using it. The rear wall of the socket that fits over the cartridge valve stem fractured:

American Standard Faucet Handle – broken mount

Having no water in the kitchen is not to be tolerated, so I applied a redneck fix while pondering the problem:

Kitchen Faucet – redneck handle repair

Based on that comment, I called the American Standard hotline (800-442-1920), described the situation, and they’re sending a replacement handle and cartridge. Evidently the new handle won’t fit the old cartridge, which makes me feel better about not stockpiling repair parts, even while I now wonder what the new cartridge part number might be and how you’d tell them apart.

Anyhow, the redneck fix wouldn’t suffice for the next week; I needed something slightly more permanent. The broken wall fit neatly in place on the mount, but:

• It must withstand far more force than a simple glue joint can provide
• I can’t machine square holes
• Wrapping a metal sleeve around the mount seemed like too much work

You undoubtedly saw this coming a while ago:

Am Std Faucet Handle Sleeve – solid model

The mount tapers slightly from the handle body toward the open end to provide draft for the molding process. I applied a hull() operator to two thin rectangles spaced the right distance apart along the Z axis to create a positive model of the mount, which then gets subtracted from the blocky outer rectangle. The hole clears a 10-32 screw that fits the standard setscrew threads (normally hidden behind the handle’s red-and-blue button).

Unlike most printed parts I’ve done recently, the sleeve suffered from severe shrinkage along the outside walls:

Faucet handle sleeve – build distortion

The inside maintained the right shape, so I cleared the nubs with a file and pressed it in place around the mount with the rear wall snapped into position. The black plastic socket evidently isolates the handle from the valve stem and I used a stainless 10-32 screw to prevent the nightmare scenario of having the sleeve slide downward along the tapered mount and block the setscrew. Overall, it came out fine:

American Standard faucet handle – compression sleeve

However, the chunky sleeve didn’t clear the opening in the escutcheon cap, which put the cap on the windowsill for the next week. The result works much better than the redneck fix and looks almost presentable. It’s certainly less conspicuous:

American Standard faucet handle – temporary repair

I hope the new handle has a much more robust socket…

The OpenSCAD source code:

// Quick fix for broken American Standard Elite 4454 faucet handle
// Ed Nisley KE4ZNU February 2013

//- Extrusion parameters must match reality!
//  Print with +2 shells and 3 solid layers

ThreadThick = 0.25;
ThreadWidth = 2.0 * ThreadThick;

HoleFinagle = 0.4;
HoleFudge = 1.00;

function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);
function HoleAdjust(Diameter) = HoleFudge*Diameter + HoleFinagle;

Protrusion = 0.1;           // make holes end cleanly

//----------------------
// Dimensions

Wall = 5.0;

Slice = ThreadThick;                // minimal thickness for hull object

ShaftEnd = [11.6,17.8,Slice];
ShaftBase = [12.1,18.8,Slice];
ShaftLength = 19.0;

Block = [(ShaftBase[0] + 2*Wall),(ShaftBase[1] + 2*Wall),ShaftLength - Protrusion];

ScrewOffset = 6.5;          // from End
ScrewDia = 5.0;             // clearance

//----------------------
// Useful routines

module ShowPegGrid(Space = 10.0,Size = 1.0) {

    Range = floor(50 / Space);

    for (x=[-Range:Range])
        for (y=[-Range:Range])
            translate([x*Space,y*Space,Size/2])
            %cube(Size,center=true);

}

module PolyCyl(Dia,Height,ForceSides=0) {           // based on nophead's polyholes
  Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);
  FixDia = Dia / cos(180/Sides);
  cylinder(r=HoleAdjust(FixDia)/2,h=Height,$fn=Sides);
}

//----------------------
// Model the handle's tapered shaft

module Shaft() {

    hull() {
        translate([0,0,ShaftLength - Slice/2])
            cube(ShaftEnd, center=true);
        translate([0,0,Slice/2])
            cube(ShaftBase, center=true);
    }

}

//----------------------
// Build it!

ShowPegGrid();

difference() {
    translate([0,0,ShaftLength/2])
        cube(Block,center=true);
    Shaft();
    translate([0,0,ShaftLength - ScrewOffset])
        rotate([-90,0,0])
            PolyCyl(ScrewDia,ShaftBase[1],6);
}

Three rack protectors have gone missing over the last few months, presumably being digested by the dishwasher’s grinder, so I ran off another batch:

Dishwasher Rack Protectors – on platform

I used the original solid model, shown here with the support structure outside for visibility:

Dishwasher rack protector – support model

I re-sliced the model to pick up whatever printer config tweakage happened since then. Those ribbed doodads snapped out easily and, in fact, some remained bonded to the platform:

Dishwasher Rack Protectors – support structures

No finishing required: just slide them over the pins atop a blob of acrylic caulk. Despite the few missing protectors, it does a good job of bonding them to the rack and sealing gaps in the worn vinyl coating.

I picked up a jar of ReRack glop on closeout duing my last pass through the Big Box Home Repair Store. It seemed a bit stiff, so I’ve added generous dollops of xylene, acetone, and MEK to thin it out; that’ll take a while to stabilize.

After beating the Samsung’s nozzle handle and hose into submission, I made a set of floor brush strips for the hard-floor attachment:

Floor brush strips – replacements in place

The original brushes had non-woven felt glued to a cleverly molded strip of white plastic, which lasted not very long at all. I’d replaced them (*) with wool fabric glued to hand-hewn strips of polypropylene cut from the usual blister pack material, but that was so labor-intensive as to make no sense at all; it did show that replacement brushes would work, though, which was the whole point. This view looks through a finished strip to the urethane glue and wool fabric:

Floor brush strip – manual version

Fortunately, there’s an easier way to make the strips:

Floor brush strip – solid model

Note that the smaller tab (the one in the front) is not centered on the midline. The openings for the larger tab in the floor brush housing seem to have a small offset, but it’s not worth worrying about. The printed ones are 4 layers thick, but I think 3 layers will work as well; that’s what the OpenSCAD source will produce.

This is one of the few situation where the hand-knitted top surface of a 3D-printed object is an advantage: that, plus the holes, provides enough griptitude for urethane glue to hold the fabric strips firmly in place.

Obviously, you print them in multiples:

Floor brush strips – on platform

A trial fit:

Floor brush strip – trial fit

They really are bowed slightly outward in the middle, which ensures there’s more pressure on the middle of the strip against the floor. I think the weird indented pattern in the brush housing under the strips was for a complex spring assembly that never made it into production; the OEM strips looked just like the ones I’m making, minus the perforations.

I glued two strips individually to make sure everything lined up, then glued these two in one operation and separated them with a razor knife:

Floor brush strips – gluing fabric

(*) It goes without saying that OEM replacement brushes weren’t available and, in fact, they have never been available at any time when we’ve owned the vacuum cleaner. Maybe I’m not looking in the right place, but so it goes.

The OpenSCAD source code, which you’ll want to print with Multiply set to maybe 8:

// Samsung Vacuum cleaner nozzle floor strips
// Ed Nisley KE4ZNU January 2013

Layout = "Build";			// Show, Build

//- Extrusion parameters must match reality!
//  Print with +0 shells and 3 solid layers

ThreadThick = 0.25;
ThreadWidth = 2.0 * ThreadThick;

HoleWindage = 0.75;

function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

Protrusion = 0.1;           // make holes end cleanly

//----------------------
// Dimensions

Body = [6.0,59.0,3*ThreadThick];	// width, length, thick

Tab1 = [4.5,5.0,0.0];				// width, length, offset from centerline
Tab2 = [3.5,5.0,0.5];

HoleOC = 8.0;						// adhesive anchoring holes
HoleDia = 1.0;
HoleSides = 4;
HoleMax = floor(Body[1]/(2*HoleOC));

echo("HoleMax: ",HoleMax);

//----------------------
// Useful routines

module PolyCyl(Dia,Height,ForceSides=0) {           // based on nophead's polyholes

Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);

FixDia = Dia / cos(180/Sides);

cylinder(r=(FixDia + HoleWindage)/2,
         h=Height,
         $fn=Sides);
}

module ShowPegGrid(Space = 10.0,Size = 1.0) {

    Range = floor(50 / Space);

    for (x=[-Range:Range])
        for (y=[-Range:Range])
            translate([x*Space,y*Space,Size/2])
            %cube(Size,center=true);

}

module BackingStrip() {

	difference() {
		union() {
			translate([0,0,Body[2]/2])
			cube(Body,center=true);
			translate([Tab1[2],-1*Body[1]/2,Body[2]/2])
			cube([Tab1[0],2*Tab1[1],Body[2]],center=true);
			translate([Tab2[2],+1*Body[1]/2,Body[2]/2])
			cube([Tab2[0],2*Tab2[1],Body[2]],center=true);
		}
		for (i = [-HoleMax:HoleMax])
			translate([0,i*HoleOC,-Protrusion])
			rotate(45)
			PolyCyl(HoleDia,(Body[2] + 2*Protrusion),HoleSides);
	}
}

//----------------------
// Build it!

ShowPegGrid();

if (Layout == "Show")
	BackingStrip();

if (Layout == "Build")
	rotate(90) BackingStrip();